Convert to python-single-r1.

(Portage version: 2.2.15/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)

2 files changed, 58 insertions, 2 deletions

diff --git a/app-i18n/ibus-sunpinyin/ChangeLog b/app-i18n/ibus-sunpinyin/ChangeLog
index 67102fb01c82..cf363472ef85 100644
--- a/app-i18n/ibus-sunpinyin/ChangeLog
+++ b/app-i18n/ibus-sunpinyin/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for app-i18n/ibus-sunpinyin
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-i18n/ibus-sunpinyin/ChangeLog,v 1.11 2013/02/03 11:21:03 pacho Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-i18n/ibus-sunpinyin/ChangeLog,v 1.12 2014/12/27 11:09:05 mgorny Exp $
+
+*ibus-sunpinyin-2.0.4_pre20130108-r2 (27 Dec 2014)
+
+  27 Dec 2014; Michał Górny <mgorny@gentoo.org>
+  +ibus-sunpinyin-2.0.4_pre20130108-r2.ebuild:
+  Convert to python-single-r1.
 
   03 Feb 2013; Pacho Ramos <pacho@gentoo.org> metadata.xml:
   Cleanup due #333419
diff --git a/app-i18n/ibus-sunpinyin/ibus-sunpinyin-2.0.4_pre20130108-r2.ebuild b/app-i18n/ibus-sunpinyin/ibus-sunpinyin-2.0.4_pre20130108-r2.ebuild
new file mode 100644
index 000000000000..03bbff2ce959
--- /dev/null
+++ b/app-i18n/ibus-sunpinyin/ibus-sunpinyin-2.0.4_pre20130108-r2.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-i18n/ibus-sunpinyin/ibus-sunpinyin-2.0.4_pre20130108-r2.ebuild,v 1.1 2014/12/27 11:09:05 mgorny Exp $
+
+EAPI=5
+PYTHON_COMPAT=( python2_7 )
+inherit python-single-r1 scons-utils toolchain-funcs
+
+DESCRIPTION="The SunPinYin IMEngine for IBus Framework"
+HOMEPAGE="https://sunpinyin.googlecode.com/"
+SRC_URI="http://dev.gentoo.org/~yngwin/distfiles/sunpinyin-${PV}.tar.xz"
+
+LICENSE="LGPL-2.1 CDDL"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+nls"
+
+RDEPEND="${PYTHON_DEPS}
+	app-i18n/ibus[python,${PYTHON_USEDEP}]
+	~app-i18n/sunpinyin-${PV}:=
+	nls? ( virtual/libintl )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )"
+REQUIRED_USE=${PYTHON_REQUIRED_USE}
+
+src_unpack() {
+	default
+	mv "${WORKDIR}/sunpinyin-${PV}" "${S}" || die
+}
+
+src_prepare() {
+	sed -i -e "s/python/${EPYTHON}/" wrapper/ibus/setup/ibus-setup-sunpinyin.in || die
+}
+
+src_configure() {
+	tc-export CXX
+	myesconsargs=(
+		--prefix="${EPREFIX}"/usr
+		--libexecdir="${EPREFIX}"/usr/libexec
+	)
+}
+
+src_compile() {
+	escons -C wrapper/ibus
+}
+
+src_install() {
+	escons -C wrapper/ibus --install-sandbox="${ED}" install
+}