blob: a1fd03bd06ed4e6d095665103c99c76c7ec31e1e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
|
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-fs/cvmfs/cvmfs-2.1.20.0_p05.ebuild,v 1.2 2015/08/07 19:00:39 bicatali Exp $
EAPI=5
inherit cmake-utils linux-info
MYP=${PN}-${PV/_p/-fix}
DESCRIPTION="HTTP read-only file system for distributing software"
HOMEPAGE="http://cernvm.cern.ch/portal/filesystem"
SRC_URI="https://github.com/cvmfs/${PN}/archive/${MYP}.tar.gz"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="aufs +client debug doc test server"
CDEPEND="
dev-cpp/gtest
dev-db/sqlite:3=
dev-libs/openssl:0
net-libs/pacparser:0=
net-misc/curl:0=[adns]
sys-apps/attr
sys-libs/zlib:0=
client? (
>=dev-cpp/sparsehash-1.12
dev-libs/leveldb:0=
sys-fs/fuse:0= )
server? (
>=dev-python/geoip-python-1.3.1
>=dev-cpp/tbb-4.3:0= )"
RDEPEND="${CDEPEND}
client? ( net-fs/autofs )
aufs? (
|| (
sys-fs/aufs3
sys-fs/aufs4
sys-kernel/aufs-sources
)
)"
DEPEND="${CDEPEND}
virtual/pkgconfig
doc? ( app-doc/doxygen[dot] )"
S="${WORKDIR}/${PN}-${MYP}"
pkg_setup() {
if use server; then
if use aufs; then
CONFIG_CHECK="
~AUFS_FS
~EXT4_FS_POSIX_ACL ~EXT4_FS_SECURITY
"
ERROR_AUFS_FS="CONFIG_AUFS_FS: is required to be set if and only if aufs-sources are used"
else
CONFIG_CHECK="~OVERLAY_FS"
fi
linux-info_pkg_setup
fi
}
PATCHES=(
"${FILESDIR}"/${P}-geoip-missing-cmake.patch
"${FILESDIR}"/${P}-cares-underlink.patch
"${FILESDIR}"/${P}-overlayfs.patch
)
src_prepare() {
cmake-utils_src_prepare
# gentoo stuff
sed -i -e 's/COPYING//' CMakeLists.txt || die
rm bootstrap.sh || die
sed -i \
-e "s:cvmfs-\${CernVM-FS_VERSION_STRING}:${PF}:" \
CMakeLists.txt || die
# should be gone in >= 2.2
sed -i \
-e 's|/etc/auto.master|/etc/autofs/auto.master|g' \
-e 's|/etc/sysconfig/autofs|/etc/conf.d/autofs|g' \
cvmfs/cvmfs_config || die
sed -i \
-e 's|${res_path}/conf.d|${res_path/modules.d|' \
cvmfs/cvmfs_server || die
# hack for bundled vjson
# vjson not worth unbundling, already upstream obsolete
# upstream replaced by gason with a new api
if use server; then
sed -i \
-e 's/g++/$(CXX)/g' \
-e 's/-O2/$(CXXFLAGS)/g' \
-e 's/ar/$(AR)/' \
-e 's/ranlib/$(RANLIB)/' \
externals/vjson/src/Makefile || die
mkdir -p "${WORKDIR}/${P}_build"/externals/build_vjson
cp externals/vjson/src/* \
"${WORKDIR}/${P}_build"/externals/build_vjson/ || die
fi
}
src_configure() {
local mycmakeargs=(
-DGEOIP_BUILTIN=OFF
-DGOOGLETEST_BUILTIN=OFF
-DLEVELDB_BUILTIN=OFF
-DLIBCURL_BUILTIN=OFF
-DPACPARSER_BUILTIN=OFF
-DSPARSEHASH_BUILTIN=OFF
-DSQLITE3_BUILTIN=OFF
-DTBB_PRIVATE_LIB=OFF
-DZLIB_BUILTIN=OFF
$(cmake-utils_use debug BUILD_SERVER_DEBUG)
$(cmake-utils_use server BUILD_SERVER)
$(cmake-utils_use client BUILD_CVMFS)
$(cmake-utils_use client BUILD_LIBCVMFS)
$(cmake-utils_use client INSTALL_MOUNT_SCRIPTS)
$(cmake-utils_use test BUILD_UNITTESTS)
)
cmake-utils_src_configure
}
src_compile() {
cmake-utils_src_compile
if use doc; then
cd doc
doxygen cvmfs.doxy || die
fi
}
src_install() {
cmake-utils_src_install
use doc && dohtml -r doc/html/*
}
pkg_config() {
if use client; then
einfo "Setting up CernVM-FS client"
cvmfs_config setup
einfo "Now edit ${EROOT%/}/etc/cvmfs/default.local"
einfo "and restart the autofs service"
fi
}
|
GitWeb