lxqt-base/lxqt-panel: add 2.0.0

Signed-off-by: Jimi Huotari <chiitoo@gentoo.org>

2 files changed, 118 insertions, 0 deletions

diff --git a/lxqt-base/lxqt-panel/Manifest b/lxqt-base/lxqt-panel/Manifest
new file mode 100644
index 00000000..4e5b5717
--- /dev/null
+++ b/lxqt-base/lxqt-panel/Manifest
@@ -0,0 +1 @@
+DIST lxqt-panel-2.0.0.tar.xz 659368 BLAKE2B 6d21ba65ad0ec99373e834a35a6cd32921c7c80311553219278c695c4231c58dbf0b282f93810750edd937127d4d6b2f1f01d84b20fffcf24a3256502c97733a SHA512 2045848c2840a51cb15f546fa5bbcd63527ebf1335048073fd6bc45959986a3cb73f795c270a82eef4ed62184b193fc4c66926e7902896c4810a425853e135f1
diff --git a/lxqt-base/lxqt-panel/lxqt-panel-2.0.0.ebuild b/lxqt-base/lxqt-panel/lxqt-panel-2.0.0.ebuild
new file mode 100644
index 00000000..07f2ef0e
--- /dev/null
+++ b/lxqt-base/lxqt-panel/lxqt-panel-2.0.0.ebuild
@@ -0,0 +1,117 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="LXQt desktop panel and plugins"
+HOMEPAGE="https://lxqt-project.org/"
+
+MY_PV="$(ver_cut 1-2)"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/lxqt/${PN}.git"
+else
+	SRC_URI="https://github.com/lxqt/${PN}/releases/download/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="LGPL-2.1 LGPL-2.1+"
+SLOT="0"
+IUSE="
+	+alsa colorpicker cpuload +desktopswitch +directorymenu dom +kbindicator
+	+mainmenu +mount networkmonitor pulseaudio +quicklaunch lm-sensors +showdesktop
+	+spacer +statusnotifier sysstat +taskbar tray +volume +worldclock
+"
+
+# Work around a missing header issue: https://bugs.gentoo.org/666278
+REQUIRED_USE="
+	|| ( desktopswitch mainmenu showdesktop taskbar )
+	volume? ( || ( alsa pulseaudio ) )
+"
+
+BDEPEND="
+	>=dev-qt/qttools-6.6:6[linguist]
+	>=dev-util/lxqt-build-tools-2.0.0
+	virtual/pkgconfig
+"
+DEPEND="
+	>=dev-libs/libqtxdg-4.0.0
+	>=dev-qt/qtbase-6.6:6[dbus,gui,widgets,xml]
+	>=dev-qt/qtsvg-6.6:6
+	kde-frameworks/kwindowsystem:6[X]
+	kde-plasma/layer-shell-qt:6
+	>=lxde-base/menu-cache-1.1.0
+	=lxqt-base/liblxqt-${MY_PV}*:=
+	=lxqt-base/lxqt-globalkeys-${MY_PV}*
+	=lxqt-base/lxqt-menu-data-${MY_PV}*
+	x11-libs/libX11
+	cpuload? ( sys-libs/libstatgrab )
+	kbindicator? ( x11-libs/libxkbcommon )
+	lm-sensors? ( sys-apps/lm-sensors:= )
+	mount? ( kde-frameworks/solid:6 )
+	networkmonitor? ( sys-libs/libstatgrab )
+	statusnotifier? (
+		dev-libs/libdbusmenu-lxqt
+		>=dev-qt/qtbase-6.6:6[concurrent]
+	)
+	sysstat? ( >=lxqt-base/libsysstat-1.0.0 )
+	tray? (
+		x11-libs/libxcb:=
+		x11-libs/libXcomposite
+		x11-libs/libXdamage
+		x11-libs/libXrender
+		x11-libs/libXtst
+		x11-libs/xcb-util
+		x11-libs/xcb-util-image
+	)
+	volume? (
+		alsa? ( media-libs/alsa-lib )
+		pulseaudio? (
+			media-libs/libpulse
+			media-sound/pavucontrol-qt
+		)
+	)
+"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	local mycmakeargs=(
+		# Plugins
+		-DCOLORPICKER_PLUGIN=$(usex colorpicker)
+		-DCPULOAD_PLUGIN=$(usex cpuload)
+		-DDESKTOPSWITCH_PLUGIN=$(usex desktopswitch)
+		-DDIRECTORYMENU_PLUGIN=$(usex directorymenu)
+		-DDOM_PLUGIN=$(usex dom)
+		-DKBINDICATOR_PLUGIN=$(usex kbindicator)
+		-DMAINMENU_PLUGIN=$(usex mainmenu)
+		-DMOUNT_PLUGIN=$(usex mount)
+		-DNETWORKMONITOR_PLUGIN=$(usex networkmonitor)
+		-DQUICKLAUNCH_PLUGIN=$(usex quicklaunch)
+		-DSENSORS_PLUGIN=$(usex lm-sensors)
+		-DSHOWDESKTOP_PLUGIN=$(usex showdesktop)
+		-DSPACER_PLUGIN=$(usex spacer)
+		-DSTATUSNOTIFIER_PLUGIN=$(usex statusnotifier)
+		-DSYSSTAT_PLUGIN=$(usex sysstat)
+		-DTASKBAR_PLUGIN=$(usex taskbar)
+		-DTRAY_PLUGIN=$(usex tray)
+		-DVOLUME_PLUGIN=$(usex volume)
+		-DWORLDCLOCK_PLUGIN=$(usex worldclock)
+	)
+
+	if use volume; then
+		mycmakeargs+=(
+			-DVOLUME_USE_ALSA=$(usex alsa)
+			-DVOLUME_USE_PULSEAUDIO=$(usex pulseaudio)
+		)
+	fi
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	doman panel/man/*.1
+}