net-misc/connman: bump to 1.38

Package-Manager: Portage-2.3.88, Repoman-2.3.20
Signed-off-by: Ben Kohler <bkohler@gentoo.org>

2 files changed, 101 insertions, 0 deletions

diff --git a/net-misc/connman/Manifest b/net-misc/connman/Manifest
index 5cfbde77be1c..6710329589ca 100644
--- a/net-misc/connman/Manifest
+++ b/net-misc/connman/Manifest
@@ -1 +1,2 @@
 DIST connman-1.37.tar.xz 707752 BLAKE2B ad8993764a444d205b0a8cf1ad38acc249a1a28014e6f4e5a89c8662194ad2e2ee6091b51445b88a885808461413b3aaf88eeb7b75a32f417b578d2da80a2e9f SHA512 5d5363105aedd0c9d609dd5c64eb832d9ff80923a944d9d3738337a61f180ded227f2ae1ff7912bed8826b35f0cfd20488e3ffd3801f0e53e90f98498e19efb6
+DIST connman-1.38.tar.xz 749288 BLAKE2B 3f0ec95c87d9b3bf4f188e2523cb8ed97f462953ed95180fadf98bfe0d01c67a3b73e18e39d616e9299fa0251b9a86afea6161b9e280ae6999eb66e6bd5c4406 SHA512 9c8f77c4dd62763ccb9ea5cc5d285a8a1c51bb09a82eafc73246231557a4f627ae1e5e4a9df5e104457390ebba643349d7d67800a4ee4c17c6dceff192afe8d4
diff --git a/net-misc/connman/connman-1.38.ebuild b/net-misc/connman/connman-1.38.ebuild
new file mode 100644
index 000000000000..937b54ecf834
--- /dev/null
+++ b/net-misc/connman/connman-1.38.ebuild
@@ -0,0 +1,100 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+inherit autotools systemd tmpfiles
+
+if [[ ${PV} == *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://git.kernel.org/pub/scm/network/connman/connman.git"
+else
+	SRC_URI="https://www.kernel.org/pub/linux/network/${PN}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+fi
+
+DESCRIPTION="Provides a daemon for managing internet connections"
+HOMEPAGE="https://01.org/connman"
+
+LICENSE="GPL-2"
+SLOT="0"
+
+IUSE="bluetooth debug doc +ethernet examples iptables iwd l2tp networkmanager
++nftables ofono openconnect openvpn policykit pptp tools vpnc +wifi wireguard
+wispr"
+
+REQUIRED_USE="^^ ( iptables nftables )"
+BDEPEND="virtual/pkgconfig"
+RDEPEND=">=dev-libs/glib-2.16
+	>=sys-apps/dbus-1.2.24
+	sys-libs/readline:0=
+	bluetooth? ( net-wireless/bluez )
+	iptables? ( >=net-firewall/iptables-1.4.8 )
+	iwd? ( net-wireless/iwd )
+	l2tp? ( net-dialup/xl2tpd )
+	nftables? (
+		>=net-libs/libnftnl-1.0.4:0=
+		>=net-libs/libmnl-1.0.0:0= )
+	ofono? ( net-misc/ofono )
+	openconnect? ( net-vpn/openconnect )
+	openvpn? ( net-vpn/openvpn )
+	policykit? ( sys-auth/polkit )
+	pptp? ( net-dialup/pptpclient )
+	vpnc? ( net-vpn/vpnc )
+	wifi? ( >=net-wireless/wpa_supplicant-2.0[dbus] )
+	wireguard? ( >=net-libs/libmnl-1.0.0:0= )
+	wispr? ( net-libs/gnutls )"
+
+DEPEND="${RDEPEND}
+	>=sys-kernel/linux-headers-2.6.39"
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--localstatedir=/var \
+		--with-systemdunitdir=$(systemd_get_systemunitdir) \
+		--with-tmpfilesdir="${EPREFIX}"/usr/lib/tmpfiles.d \
+		--enable-client \
+		--enable-datafiles \
+		--enable-loopback=builtin \
+		$(use_enable bluetooth bluetooth builtin) \
+		$(use_enable debug) \
+		$(use_enable ethernet ethernet builtin) \
+		$(use_enable examples test) \
+		$(use_enable iwd) \
+		$(use_enable l2tp l2tp builtin) \
+		$(use_enable networkmanager nmcompat) \
+		$(use_enable ofono ofono builtin) \
+		$(use_enable openconnect openconnect builtin) \
+		$(use_enable openvpn openvpn builtin) \
+		$(use_enable policykit polkit builtin) \
+		$(use_enable pptp pptp builtin) \
+		$(use_enable tools) \
+		$(use_enable vpnc vpnc builtin) \
+		$(use_enable wifi wifi builtin) \
+		$(use_enable wireguard) \
+		$(use_enable wispr wispr builtin) \
+		--with-firewall=$(usex iptables "iptables" "nftables" ) \
+		--disable-iospm \
+		--disable-hh2serial-gps
+}
+
+src_install() {
+	default
+	dobin client/connmanctl
+
+	if use doc; then
+		dodoc doc/*.txt
+	fi
+	keepdir /usr/lib/${PN}/scripts
+	keepdir /var/lib/${PN}
+	newinitd "${FILESDIR}"/${PN}.initd2 ${PN}
+	newconfd "${FILESDIR}"/${PN}.confd ${PN}
+}
+
+pkg_postinst() {
+	tmpfiles_process /usr/lib/tmpfiles.d/connman_resolvconf.conf
+}