app-dicts/gnome-dictionary: ebuild tweaks

* Always enable ipv6, as it imposes no extra deps and will still do upstream
  build system checks that it has everything needed
* Pass optimizing CFLAGS, which upstream only does for release buildtype, not
  plain buildtype

Package-Manager: Portage-3.0.20, Repoman-3.0.2
Signed-off-by: Mart Raudsepp <leio@gentoo.org>

1 files changed, 51 insertions, 0 deletions

diff --git a/app-dicts/gnome-dictionary/gnome-dictionary-40.0-r1.ebuild b/app-dicts/gnome-dictionary/gnome-dictionary-40.0-r1.ebuild
new file mode 100644
index 000000000000..4383ff0b33b0
--- /dev/null
+++ b/app-dicts/gnome-dictionary/gnome-dictionary-40.0-r1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit flag-o-matic gnome.org gnome2-utils meson xdg
+
+DESCRIPTION="Dictionary utility for GNOME"
+HOMEPAGE="https://wiki.gnome.org/Apps/Dictionary"
+
+LICENSE="GPL-2+ LGPL-2.1+ FDL-1.1+"
+SLOT="0" # does not provide a public libgdict-1.0.so anymore
+IUSE=""
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+DEPEND="
+	>=dev-libs/glib-2.42:2
+	>=x11-libs/gtk+-3.21.2:3
+"
+RDEPEND="${DEPEND}
+	gnome-base/gsettings-desktop-schemas
+"
+BDEPEND="
+	app-text/docbook-xsl-stylesheets
+	app-text/docbook-xml-dtd:4.3
+	dev-libs/libxslt
+	dev-util/glib-utils
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+src_configure() {
+	# Replicate what a release buildtype would set, as we use -Dbuildtype=plain
+	append-cflags -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DG_DISABLE_CAST_CHECKS
+
+	local emesonargs=(
+		-Dipv6=true
+		-Dbuild_man=true
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}