openstack p2, newton is done, will add heat later

2 files changed, 82 insertions, 0 deletions

diff --git a/dev-python/os-client-config/Manifest b/dev-python/os-client-config/Manifest
index b8e62b592c1b..e8878eb626c7 100644
--- a/dev-python/os-client-config/Manifest
+++ b/dev-python/os-client-config/Manifest
@@ -1 +1,2 @@
 DIST os-client-config-1.16.0.tar.gz 53367 SHA256 d25dfb1b74552339442875bedb1e9328de66c5644b8dff0b31cc140f1d6ac9fd SHA512 a10a877dd3bc0245c6bbdaa0cb6daa5a17b519cc4fa73b368626a2e58dd44427309e1d839a3db14128ab4ed4d12fd36aaf366617ded88e14335ced8929c7f527 WHIRLPOOL 58fa3908c9ab756a610e4ce9cd99bf4f0e33602a79a773b71b8c5d5677c251d92b0e13ae33bf5d7ce9c671f672e0edef3d5780d9d806e8c72a2790f369ad5724
+DIST os-client-config-1.21.1.tar.gz 62581 SHA256 ad4c2d07c0468c8d11916ea690b977abb3e903e0c599f6eae02c4776edab2f96 SHA512 74d16d0f3e2980c1ef07134de8bdcb867e80226cb23eeaaeb95a534a2f807b186e7807d14df20003f56e7aa3bd72cafa7839c40937e52d50f8b21a40e7eba00b WHIRLPOOL 13e34ef0e20b16abc9c780d0566a516a2beb41d658f493e15f73a7c5eb6ae85fb7c27b5b60e15fbaabfd4435061400c7609084a4e649d9ab75595f1940c13d2f
diff --git a/dev-python/os-client-config/os-client-config-1.21.1.ebuild b/dev-python/os-client-config/os-client-config-1.21.1.ebuild
new file mode 100644
index 000000000000..1590a40beed0
--- /dev/null
+++ b/dev-python/os-client-config/os-client-config-1.21.1.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+PYTHON_COMPAT=( python{2_7,3_{4,5}} )
+
+inherit distutils-r1
+
+DESCRIPTION="OpenStack Client Configuation Library"
+HOMEPAGE="http://www.openstack.org/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="doc test"
+
+CDEPEND="dev-python/pbr[${PYTHON_USEDEP}]"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	${CDEPEND}
+	test? (
+		dev-python/extras[${PYTHON_USEDEP}]
+		>=dev-python/fixtures-0.3.14[${PYTHON_USEDEP}]
+		>=dev-python/jsonschema-2.0.0[${PYTHON_USEDEP}]
+		!~dev-python/jsonschema-2.5.0[${PYTHON_USEDEP}]
+		<dev-python/jsonschema-3.0.0[${PYTHON_USEDEP}]
+		>=dev-python/mock-1.2[${PYTHON_USEDEP}]
+		>=dev-python/python-glanceclient-0.18.0[${PYTHON_USEDEP}]
+		>=dev-python/python-keystoneclient-1.1.0[${PYTHON_USEDEP}]
+		>=dev-python/subunit-0.0.18[${PYTHON_USEDEP}]
+		>=dev-python/oslotest-1.5.1[${PYTHON_USEDEP}]
+		>=dev-python/reno-0.1.1[${PYTHON_USEDEP}]
+		>=dev-python/testrepository-0.0.18[${PYTHON_USEDEP}]
+		>=dev-python/testscenarios-0.4[${PYTHON_USEDEP}]
+		>=dev-python/testtools-0.9.36[${PYTHON_USEDEP}]
+		!~dev-python/testtools-1.2.0[${PYTHON_USEDEP}]
+	)
+	doc? (
+		>=dev-python/oslo-sphinx-2.5.0[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-1.1.2[${PYTHON_USEDEP}]
+		!~dev-python/sphinx-1.2.0[${PYTHON_USEDEP}]
+		<dev-python/sphinx-1.3[${PYTHON_USEDEP}]
+	)
+"
+RDEPEND="
+	${CDEPEND}
+	>=dev-python/pyyaml-3.1.0[${PYTHON_USEDEP}]
+	>=dev-python/appdirs-1.3.0[${PYTHON_USEDEP}]
+	>=dev-python/keystoneauth-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/requestsexceptions-1.1.1[${PYTHON_USEDEP}]
+"
+
+python_prepare_all() {
+	sed -i '/^hacking/d' test-requirements.txt || die
+	local PATCHES=(
+		"${FILESDIR}"/test_get_all_clouds.patch
+	)
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && esetup.py build_sphinx
+}
+
+python_test() {
+	distutils_install_for_testing
+
+	rm -rf .testrepository || die "couldn't remove '.testrepository' under ${EPTYHON}"
+
+	testr init || die "testr init failed under ${EPYTHON}"
+	testr run || die "testr run failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/build/html/. )
+
+	distutils-r1_python_install_all
+}