media-sound/gnome-music: bump to 3.26.2

Compatible with and requires tracker-2 (and actually uses a
new tracker-2 feature - title-order sorting, which ignores
"The" and such for sort)

Bug: https://bugs.gentoo.org/672308
Package-Manager: Portage-2.3.52, Repoman-2.3.12
Signed-off-by: Mart Raudsepp <leio@gentoo.org>

2 files changed, 65 insertions, 0 deletions

diff --git a/media-sound/gnome-music/Manifest b/media-sound/gnome-music/Manifest
index 5eb283fdb7b1..32d7bcd264bd 100644
--- a/media-sound/gnome-music/Manifest
+++ b/media-sound/gnome-music/Manifest
@@ -1 +1,2 @@
 DIST gnome-music-3.24.2.tar.xz 1557848 BLAKE2B 329d60da4c2c601524e01bddf086ea699bc10ea311d440ae24af0a83829d7ad4c351963e1b08bd30a8538c9b9987d9f2a41f95690ae31e75c06aac0cc9db2dcf SHA512 a922c80f922b9231e9bbe0cbd1fd33c059c719350c250dbb24316224e3306de7576303119fc9ec303f569559c36d6b076b5ec1076b4f9221a8fb133dcd9f040e
+DIST gnome-music-3.26.2.tar.xz 1563244 BLAKE2B 5a5d27b34470a49a752cb67a1040e227595fd15c6ca4f7656818636d614dfef8ec082dc014ea05c271f512f7c362dc2f81a38359ef04e0663467f62ff3ac2423 SHA512 e8efe31003a54b6cfea151c5402c4d06e48928be7b79332f7f9fb8a567ff7d0d42a43e943398ad6cb7e391d0162322c7fde74922a4b16e52ec24691cc1bfc5b0
diff --git a/media-sound/gnome-music/gnome-music-3.26.2.ebuild b/media-sound/gnome-music/gnome-music-3.26.2.ebuild
new file mode 100644
index 000000000000..c88b4dca273b
--- /dev/null
+++ b/media-sound/gnome-music/gnome-music-3.26.2.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python{3_4,3_5,3_6} )
+
+inherit gnome2 python-single-r1
+
+DESCRIPTION="Music management for Gnome"
+HOMEPAGE="https://wiki.gnome.org/Apps/Music"
+
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE=""
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+KEYWORDS="~amd64 ~x86"
+
+COMMON_DEPEND="
+	${PYTHON_DEPS}
+	>=app-misc/tracker-1.99.1:=[introspection(+)]
+	>=dev-python/pygobject-3.21.1:3[cairo,${PYTHON_USEDEP}]
+	>=dev-libs/glib-2.28:2
+	>=dev-libs/gobject-introspection-1.35.9:=
+	>=media-libs/grilo-0.3.4:0.3[introspection]
+	>=media-libs/libmediaart-1.9.1:2.0[introspection]
+	>=x11-libs/gtk+-3.19.3:3[introspection]
+"
+# xdg-user-dirs-update needs to be there to create needed dirs
+# https://bugzilla.gnome.org/show_bug.cgi?id=731613
+RDEPEND="${COMMON_DEPEND}
+	|| (
+		>=app-misc/tracker-miners-1.99.1[gstreamer]
+		>=app-misc/tracker-miners-1.99.1[ffmpeg]
+	)
+	x11-libs/libnotify[introspection]
+	dev-python/dbus-python[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	media-libs/gstreamer:1.0[introspection]
+	media-libs/gst-plugins-base:1.0[introspection]
+	media-plugins/gst-plugins-meta:1.0
+	media-plugins/grilo-plugins:0.3[tracker]
+	x11-misc/xdg-user-dirs
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-util/intltool-0.26
+	dev-util/itstool
+	virtual/pkgconfig
+"
+# eautoreconf needs app-text/yelp-tools
+
+pkg_setup() {
+	python_setup
+}
+
+src_prepare() {
+	sed -e '/sys.path.insert/d' -i "${S}"/gnome-music.in || die "python fixup sed failed"
+	gnome2_src_prepare
+}
+
+src_install() {
+	gnome2_src_install
+	python_fix_shebang "${D}"usr/bin/gnome-music
+}