media-video/yle-dl: bump to 20200222

 - python3.8 support added.

Signed-off-by: Joonas Niilola <juippis@gentoo.org>

2 files changed, 69 insertions, 0 deletions

diff --git a/media-video/yle-dl/Manifest b/media-video/yle-dl/Manifest
index 9cc45c5f58fc..58e744ad3284 100644
--- a/media-video/yle-dl/Manifest
+++ b/media-video/yle-dl/Manifest
@@ -1 +1,2 @@
 DIST yle-dl-20191231.tar.gz 86479 BLAKE2B 5b39a3e68478fe71ec604f3217a4115ad1ff09fc8913c81acc7108e433349a0c524eebadeb892e01d3ed43ab163421ea59bc4ec486af710f0680107d15d13f35 SHA512 60d7aeab72e3a6c9346a9e569c9de6af154a65b326c7528ceebe3ee33dc1df62764d6f768da160524bf74ab6ad7c238658a58184726cec6b6b46e70b5701437c
+DIST yle-dl-20200222.tar.gz 87059 BLAKE2B 25d645505d67d71b3662589c77c30f905ded81e2d64874cf6036dcaf0738e521e96650543a78c18031a4477fc3bcf121e7497c980d22c84e21bebc2bd7cb154a SHA512 2b4a98c19a12812bc3c00de6173d50c78c981de0186c29021c8d88349ae88759a4987f6488d758ee5397d2b0992cd03029680bb08a4882cb2280a28807d4bf14
diff --git a/media-video/yle-dl/yle-dl-20200222.ebuild b/media-video/yle-dl/yle-dl-20200222.ebuild
new file mode 100644
index 000000000000..0270e49960a5
--- /dev/null
+++ b/media-video/yle-dl/yle-dl-20200222.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6..8} )
+DISTUTILS_USE_SETUPTOOLS=rdepend
+
+inherit distutils-r1
+
+DESCRIPTION="Download media files from Yle Areena"
+HOMEPAGE="http://aajanki.github.io/yle-dl/"
+SRC_URI="https://github.com/aajanki/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+IUSE="libav php test +youtube-dl"
+
+# Requires an active internet connection during tests
+RESTRICT="test"
+
+RDEPEND="
+	!libav? ( media-video/ffmpeg )
+	>=dev-python/attrs-18.1.0[${PYTHON_USEDEP}]
+	>=dev-python/configargparse-0.13.0[${PYTHON_USEDEP}]
+	dev-python/future[${PYTHON_USEDEP}]
+	dev-python/lxml[${PYTHON_USEDEP}]
+	dev-python/mini-amf[${PYTHON_USEDEP}]
+	dev-python/progress[${PYTHON_USEDEP}]
+	dev-python/pycryptodome[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	net-misc/wget
+	php? (
+		dev-lang/php:*[bcmath,cli,curl,simplexml]
+		>=dev-libs/openssl-1.0.2:0=
+		media-video/rtmpdump
+	)
+	youtube-dl? ( net-misc/youtube-dl[${PYTHON_USEDEP}] )
+"
+DEPEND="
+	test? (
+		${RDEPEND}
+		dev-python/pytest-runner[${PYTHON_USEDEP}]
+	)
+"
+
+DOCS=( COPYING ChangeLog README.fi README.md yledl.conf.sample )
+
+src_prepare() {
+	default
+
+	# Gentoo doesn't ship pycryptodomex with pycryptodome
+	sed -i 's/pycryptodomex/pycryptodome/g' setup.py || die
+}
+
+python_test() {
+	# For tests to run succesfully, you need to disable network stricting
+	# feature first.
+	#  FEATURES="-network-sandbox test" emerge -a yle-dl
+	esetup.py test
+}
+
+pkg_postinst() {
+	elog "Sample configuration file has been installed in "
+	elog " /usr/share/doc/yle-dl-${PV}/yledl.conf.sample.bz2"
+}