sys-libs/fts-standalone: stop renaming .pc file

Stop renaming musl-fts.pc -> fts-standalone.pc. While it might be more
pure as a name (as it might be useful on other libcs), it's not within our
gift to rename this and it has ecosystem-wide effects.

Other distributions are using the upstream name.

Also, install a symlink for the old fts-standalone name to keep broken
checks working.

While here, fix MisplacedWeakBlocker too.

Closes: https://bugs.gentoo.org/895946
Signed-off-by: Sam James <sam@gentoo.org>

1 files changed, 39 insertions, 0 deletions

diff --git a/sys-libs/fts-standalone/fts-standalone-1.2.7-r1.ebuild b/sys-libs/fts-standalone/fts-standalone-1.2.7-r1.ebuild
new file mode 100644
index 000000000000..8289451b0a60
--- /dev/null
+++ b/sys-libs/fts-standalone/fts-standalone-1.2.7-r1.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="Standalone fts library for use with musl"
+HOMEPAGE="https://github.com/pullmoll/musl-fts"
+SRC_URI="https://github.com/pullmoll/musl-fts/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/musl-fts-${PV}"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~x86"
+IUSE="static-libs"
+
+RDEPEND="!sys-libs/glibc"
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_enable static-libs static)
+}
+
+src_install() {
+	default
+
+	find "${ED}" -name '*.la' -delete || die
+
+	# Compatibility symlink (bug #895946)
+	# TODO: Drop this a while after 2024-07-02 once packages have
+	# had time to adapt/fix broken patches.
+	dosym musl-fts.pc /usr/$(get_libdir)/pkgconfig/fts-standalone.pc
+}