blob: 83ae4f6da246428d62614f681c62f3d7cba6e08e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{10..12} )
PYTHON_REQ_USE="sqlite"
inherit gnome2-utils meson python-single-r1 xdg
DESCRIPTION="Modern music player for GNOME"
HOMEPAGE="https://wiki.gnome.org/Apps/Lollypop"
# Tarballs on adishatz.org have files from Git submodule 'subprojects/po'
SRC_URI="https://adishatz.org/${PN}/${P}.tar.xz"
LICENSE="GPL-3+"
SLOT="0"
KEYWORDS="amd64 ~arm64"
IUSE="test"
REQUIRED_USE="${PYTHON_REQUIRED_USE}"
RESTRICT="!test? ( test )"
# Dependencies being checked by Meson
DEPEND="
dev-libs/glib:2
dev-libs/gobject-introspection
net-libs/libsoup:3.0[introspection]
x11-libs/gtk+:3[introspection]
${PYTHON_DEPS}
$(python_gen_cond_dep '
dev-python/pygobject:3[cairo,${PYTHON_USEDEP}]
')
"
BDEPEND="
sys-devel/gettext
virtual/pkgconfig
test? (
dev-libs/appstream-glib
dev-util/desktop-file-utils
)
"
RDEPEND="
${DEPEND}
app-crypt/libsecret[introspection]
dev-libs/totem-pl-parser[introspection]
gui-libs/libhandy:1[introspection]
media-plugins/gst-plugins-pulse
$(python_gen_cond_dep '
dev-python/beautifulsoup4[${PYTHON_USEDEP}]
dev-python/gst-python[${PYTHON_USEDEP}]
dev-python/pillow[${PYTHON_USEDEP}]
')
"
src_install() {
meson_src_install
python_optimize
python_fix_shebang "${ED}/usr/bin"
python_fix_shebang "${ED}/usr/libexec/lollypop-sp"
}
pkg_postinst() {
xdg_pkg_postinst
gnome2_schemas_update
if [[ -z ${REPLACING_VERSIONS} ]]; then
elog "Remember to install the necessary gst-plugins packages for your audio files."
elog "You can also use the gst-plugins-meta package and its USE flags."
fi
local log_yt_dlp ver
for ver in ${REPLACING_VERSIONS}; do
ver_test "${ver}" -lt "1.4.36" && log_yt_dlp=1
done
[[ ${log_yt_dlp} ]] &&
elog "Since version 1.4.36, Lollypop relies on yt-dlp instead of youtube-dl."
}
pkg_postrm() {
xdg_pkg_postrm
gnome2_schemas_update
}
|
GitWeb