version bump (bug #408053) with ebuild submission from yury fedorchenko

Package-Manager: portage-2.1.10.44/cvs/Linux i686

1 files changed, 67 insertions, 0 deletions

diff --git a/games-puzzle/jag/jag-0.3.2.ebuild b/games-puzzle/jag/jag-0.3.2.ebuild
new file mode 100644
index 000000000000..b3649bd1a6ea
--- /dev/null
+++ b/games-puzzle/jag/jag-0.3.2.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/games-puzzle/jag/jag-0.3.2.ebuild,v 1.1 2012/03/13 22:04:26 mr_bones_ Exp $
+
+EAPI=2
+inherit eutils qt4-r2 games
+
+DESCRIPTION="Arcade 2D Puzzle Game"
+HOMEPAGE="http://jag.xlabsoft.com/"
+SRC_URI="http://jag.xlabsoft.com/files/${P}-src.zip
+	http://jag.xlabsoft.com/files/${P}-data.zip"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="editor"
+
+RDEPEND="x11-libs/qt-core:4
+	x11-libs/qt-gui:4
+	x11-libs/qt-opengl:4
+	x11-libs/libXrandr
+	media-libs/libsdl[audio,video]
+	media-libs/sdl-mixer"
+DEPEND="${RDEPEND}
+	app-arch/unzip"
+
+S=${WORKDIR}/${P}-src
+
+src_prepare() {
+	mv ${WORKDIR}/${P}-data/data ${WORKDIR}/${P}-src/
+	sed -i \
+		-e "s:/usr/local/bin:${GAMES_BINDIR}:g" \
+		-e "s:/usr/local/games:${GAMES_DATADIR}:g" \
+		-e "s:LIBS += -lSDLmain:LIBS += -lSDL -lX11:" \
+		Game.pro main.cpp editor/editor.pro \
+		|| die "sed failed"
+}
+
+src_configure() {
+	qt4-r2_src_configure
+	if use editor; then
+		cd editor
+		eqmake4 editor.pro
+	fi
+}
+
+src_compile() {
+	qt4-r2_src_compile
+	if use editor; then
+		cd editor
+		qt4-r2_src_compile
+	fi
+}
+
+src_install() {
+	qt4-r2_src_install
+	newicon images/logo.png ${PN}.png
+	make_desktop_entry jag Jag
+
+	if use editor; then
+		cd editor
+		qt4-r2_src_install
+		make_desktop_entry jag-editor "Jag Level editor" ${PN}
+	fi
+
+	prepgamesdirs
+}