sys-kernel/dracut: Version bump to 011.

Package-Manager: portage-2.1.10.6/cvs/Linux x86_64

4 files changed, 264 insertions, 9 deletions

diff --git a/sys-kernel/dracut/ChangeLog b/sys-kernel/dracut/ChangeLog
index 95f745f564be..eff531fbcfc3 100644
--- a/sys-kernel/dracut/ChangeLog
+++ b/sys-kernel/dracut/ChangeLog
@@ -1,6 +1,19 @@
 # ChangeLog for sys-kernel/dracut
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-kernel/dracut/ChangeLog,v 1.26 2011/06/30 21:39:37 aidecoe Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-kernel/dracut/ChangeLog,v 1.27 2011/07/18 17:49:19 aidecoe Exp $
+
+*dracut-011 (18 Jul 2011)
+
+  18 Jul 2011; Amadeusz Żołnowski <aidecoe@gentoo.org> +dracut-011.ebuild,
+  +files/dracut-011-multipath-udev-rules.patch:
+  Version bump.
+
+  This version provides new modules:
+  - crypt-gpg
+  - shutdown
+
+  sys-fs/udev version was restricted to 168 and above and
+  sys-apps/module-init-tools to 3.8 or above.
 
   30 Jun 2011; Amadeusz Żołnowski <aidecoe@gentoo.org> -dracut-010.ebuild,
   -dracut-010-r1.ebuild, -dracut-010-r2.ebuild:
diff --git a/sys-kernel/dracut/Manifest b/sys-kernel/dracut/Manifest
index c9f0cfff3426..b89d1f366d7c 100644
--- a/sys-kernel/dracut/Manifest
+++ b/sys-kernel/dracut/Manifest
@@ -12,25 +12,28 @@ AUX dracut-010-empty-etc-ld.so.conf.d.patch 775 RMD160 0e8463dd1fabdfabab26861c4
 AUX dracut-010-multipath-udev-rules.patch 848 RMD160 99527326b1c5c33647a750d4bba2da9b6b5f0c92 SHA1 353c065322645f063fd3ae90ece7635eab8225ed SHA256 0e2215897b7cbac1bf9c84b42d6eb8af4438674934749bc339f768cba6662c18
 AUX dracut-010-rd.driver.post-fixed.patch 1080 RMD160 2ab3ff1c7fef4d8d8e1fa1f5176b42e2b390fe16 SHA1 4c7ddc8dca44138c0fede8c218487aa8787547e7 SHA256 a03f0beaf47b4afde8f4945f97ae240edc1a61d71653c8c6e5120bfcbacb530b
 AUX dracut-010-rd.driver.pre-and-blacklist-fix.patch 1152 RMD160 49981662b15e9a5bdcba577acae19c4a1ad7eb11 SHA1 88b06237813c8e0a4f6266dc2d62870e67b94671 SHA256 cc4e049e02a89a5fb4d78e42dea970f11e726608aab20b4e69d35e712c106119
+AUX dracut-011-multipath-udev-rules.patch 848 RMD160 99527326b1c5c33647a750d4bba2da9b6b5f0c92 SHA1 353c065322645f063fd3ae90ece7635eab8225ed SHA256 0e2215897b7cbac1bf9c84b42d6eb8af4438674934749bc339f768cba6662c18
 DIST dracut-007.tar.bz2 99629 RMD160 5bb9d1e89e3d7b3a024369eecb594e71a359778d SHA1 38f2e74f127f682eac4dc7da30ee0ea8debfff1f SHA256 6d58778bcf24b46c82cc72c7d6f5cc1e7bac7f3f9c33aa542052583bd00d20e1
 DIST dracut-008.tar.bz2 136218 RMD160 2804a92c99539c19af54f256da2ceca34cff110a SHA1 7a3d3133ee52d824f11c9b2ccfca56fb983bda81 SHA256 f0cb0e022064c5b2fe02af9906f19ad77000d5f1813fe6cd57b037aaee921d31
 DIST dracut-009.tar.bz2 143623 RMD160 bf9126fd1310f74bf78917f8ea374ded15e7359c SHA1 4b8efde1ac7e82d740873f051309b1fc946a21c4 SHA256 791b4167f78e5c553bdd4165f4753bbe54a3662d90fc7ef695dd15c5c95f68c7
 DIST dracut-010.tar.bz2 143576 RMD160 3b98e86fdc3a3b14c257b317852d6582de06a5c6 SHA1 cd78c8a2b2629931aaf99c5fc4ef33424d84fa1c SHA256 08df4fee439bc96f9f58fcd9ac1445cf5954fe5066643449e0d6a846d0a23ba7
+DIST dracut-011.tar.bz2 146262 RMD160 5ec3584f92590ee27e2ee6ecfbd25edead1c82a2 SHA1 0b4be17638439e54122731dca147a8b5da1bb045 SHA256 ca27f8996776eee9e462eff46d862f9e930d5c424b1af0efb2910dc5ab4d4a4a
 EBUILD dracut-007.ebuild 4817 RMD160 b9d983b8cdabc60e0cadf90f1405c76e88731cf8 SHA1 b20bb5f4ecf83aabf428a683d98d42cb3ea36db6 SHA256 6715e399fe0dafa868171a2239e4cca508396ffc09cdd8cb029930c07bef1fff
 EBUILD dracut-008-r1.ebuild 5832 RMD160 5a5f978f28be2cdef5f6df5782d623b25a417123 SHA1 6ec710509d56427941e00cf0bff6edf16d892f2a SHA256 95c03df493e91c716de5573a9a33134dd6a660a31ddbf8f9dbd7317b1d979ddc
 EBUILD dracut-008.ebuild 5745 RMD160 194d7b14c84d8411d49235a4359d6d2c6193cce6 SHA1 5346f7e5be40e78d57ec0dc2e0dcb326172a11ab SHA256 bd308a8caddf8737455439383931dd7275384e8814599a63c9eb76a0a165aa5f
 EBUILD dracut-009-r1.ebuild 5926 RMD160 1ea8662b9ba97fff4cd7213edff46dd686f9c0cb SHA1 addddc776d153fbf5df75cd5297bb3543ee2c4f3 SHA256 cbc4e30d8b9836d15c3ebc7e5614122734770ef1fa370c2b90c807ae4a8b930d
 EBUILD dracut-010-r3.ebuild 6050 RMD160 d6bf1562f9956eee52d7d54ac6824a56401b80d5 SHA1 704d2e9f53e82e06f1b904d542b926abb565f6b1 SHA256 377c77f8795b0641c1fc076d50af21544d799f56fa65e64a5aaf4a99754213d9
-MISC ChangeLog 7757 RMD160 4a484f14104cf7cc2c5a115eb070a2b8587612dc SHA1 d064d61c3162d9c7ce33c9cc35b079ca3eb7014c SHA256 5e64c1c0df3065bdead720d751ad2183b37250fbe9d59f5c859a4cf753b7de8e
+EBUILD dracut-011.ebuild 5945 RMD160 83d91c5c69415510993af9e86f173def99c90560 SHA1 60f1149dd09ec9a1856ec1d7be2d7fd6524e9344 SHA256 5ffb020b023979218a03b06ff262829eb5ba5dd7b43b1db6f509a26c52a7e7d2
+MISC ChangeLog 8096 RMD160 84d7c1463b85620b1bd16020c06f824cbea9abf7 SHA1 7693036ffdd77b8af97ef3c7d719e7cdff699eae SHA256 6ce9ad1133af829abc6148dff41c720739be3ba785f60aa0f46e2a011161bf7e
 MISC metadata.xml 1725 RMD160 b297eb03e09381e2b03d98b37755c56f5ebe546d SHA1 145aef995db3cc66ead45189d722c7939c6d0ed7 SHA256 4a4acf6ddbe7fe41200c9bab075f677d46848b09f680a2eab05921a29455316f
 -----BEGIN PGP SIGNATURE-----
 Version: GnuPG v2.0.17 (GNU/Linux)
 
-iQEcBAEBAgAGBQJODO0gAAoJEPATRTHh2/q1iI8IAIQEQFx/1NsJhcC+iFOO8eP2
-rAEd8lkk0IwSLsa6Xk+NFcPUrBQitZunA0nx9nvqcVV5vtNdRE5zsHYMD1x5Of90
-99WuJAhy76dNhXvgz5lfqQOAyghoLAWxKVe89cEOmTIFNAJIwQV+aZ3NV836ey9D
-gvNwRXnP4289rgEnkKACXrPVJ15ontp1GZ6JZk4PLA+ANZExPaiNoK+QaFBZo/6r
-LEudOAEjwl6CFZP9co3YKWMZXRP9JzQTGIVnP91BtuCv6/bhe1RH/JJb1LNhEbH7
-pALYeemLH9SvF31bJsqpZ911rg8tROau/VFVPVYKo0/NSIZAupvG3LbggqaaMVY=
-=zHkr
+iQEcBAEBAgAGBQJOJHIkAAoJEPATRTHh2/q1hPMH/0NliGvZxVLkQjvWQJ/i8Ctk
+jneKhlTyEQeC3vdFrgngNPTh42a/c42D5ukQjGRjgaeSKFu7NI3DSP/dXMUkkoAx
+Djspg01q6gL5iUaO1ENVDxBUz9mpbQOV+W1HqgAo+X2HeXLjj+l3Z0/mCKRSsi0I
+iF1eEGxNzVXJTRC19Oyjqt1Eh1oBjldcFJJ9R1Rnwqzmq/l660/759lKkEmUdver
+IMPDRnO8A68hAprCB3Jcmg7oyEGnhzCJEQJC7j0VhLdf4Pqeeww06CEc/sBV0d0F
+f1EJ8vYi/JVXG4Ka2iwqlCBSQWOnPFqviO3J/5QehYP19nKcTYv11pT8G4ArkoY=
+=NxFS
 -----END PGP SIGNATURE-----
diff --git a/sys-kernel/dracut/dracut-011.ebuild b/sys-kernel/dracut/dracut-011.ebuild
new file mode 100644
index 000000000000..a8c2437760af
--- /dev/null
+++ b/sys-kernel/dracut/dracut-011.ebuild
@@ -0,0 +1,215 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-kernel/dracut/dracut-011.ebuild,v 1.1 2011/07/18 17:49:19 aidecoe Exp $
+
+EAPI=2
+
+inherit eutils
+
+DESCRIPTION="Generic initramfs generation tool"
+HOMEPAGE="http://dracut.wiki.kernel.org"
+SRC_URI="mirror://kernel/linux/utils/boot/${PN}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~x86 ~amd64"
+
+COMMON_MODULES="
+	dracut_modules_biosdevname
+	dracut_modules_btrfs
+	dracut_modules_caps
+	dracut_modules_crypt-gpg
+	dracut_modules_gensplash
+	dracut_modules_mdraid
+	dracut_modules_multipath
+	dracut_modules_plymouth
+	dracut_modules_syslog
+	dracut_modules_xen
+	"
+NETWORK_MODULES="
+	dracut_modules_iscsi
+	dracut_modules_nbd
+	dracut_modules_nfs
+	"
+DM_MODULES="
+	dracut_modules_crypt
+	dracut_modules_dmraid
+	dracut_modules_dmsquash-live
+	dracut_modules_lvm
+	"
+IUSE_DRACUT_MODULES="${COMMON_MODULES} ${DM_MODULES} ${NETWORK_MODULES}"
+IUSE="debug selinux ${IUSE_DRACUT_MODULES}"
+RESTRICT="test"
+
+NETWORK_DEPS="net-misc/bridge-utils >=net-misc/dhcp-4.2.1-r1 sys-apps/iproute2
+	net-misc/ifenslave"
+DM_DEPS="|| ( sys-fs/device-mapper >=sys-fs/lvm2-2.02.33 )"
+
+RDEPEND="
+	>=app-shells/bash-4.0
+	>=app-shells/dash-0.5.4.11
+	>=sys-apps/baselayout-1.12.14-r1
+	>=sys-apps/module-init-tools-3.8
+	>=sys-apps/sysvinit-2.87-r3
+	>=sys-apps/util-linux-2.16
+	>=sys-fs/udev-168
+
+	debug? ( dev-util/strace )
+	selinux? ( sys-libs/libselinux sys-libs/libsepol )
+	dracut_modules_biosdevname? ( sys-apps/biosdevname )
+	dracut_modules_btrfs? ( sys-fs/btrfs-progs )
+	dracut_modules_caps? ( sys-libs/libcap )
+	dracut_modules_crypt? ( sys-fs/cryptsetup ${DM_DEPS} )
+	dracut_modules_crypt-gpg? ( app-crypt/gnupg )
+	dracut_modules_dmraid? ( sys-fs/dmraid sys-fs/multipath-tools ${DM_DEPS} )
+	dracut_modules_dmsquash-live? ( virtual/eject ${DM_DEPS} )
+	dracut_modules_gensplash? ( media-gfx/splashutils )
+	dracut_modules_iscsi? ( >=sys-block/open-iscsi-2.0.871.3 ${NETWORK_DEPS} )
+	dracut_modules_lvm? ( >=sys-fs/lvm2-2.02.33 )
+	dracut_modules_mdraid? ( sys-fs/mdadm )
+	dracut_modules_multipath? ( sys-fs/multipath-tools )
+	dracut_modules_nbd? ( sys-block/nbd ${NETWORK_DEPS} )
+	dracut_modules_nfs? ( net-fs/nfs-utils net-nds/rpcbind ${NETWORK_DEPS} )
+	dracut_modules_plymouth? ( >=sys-boot/plymouth-0.8.3-r1 )
+	dracut_modules_syslog? ( || ( app-admin/syslog-ng app-admin/rsyslog ) )
+	dracut_modules_xen? ( app-emulation/xen )
+	"
+DEPEND="
+	>=dev-libs/libxslt-1.1.26
+	app-text/docbook-xml-dtd:4.5
+	>=app-text/docbook-xsl-stylesheets-1.75.2
+	"
+
+#
+# Helper functions
+#
+
+# Returns true if any of specified modules is enabled by USE flag and false
+# otherwise.
+# $1 = list of modules (which have corresponding USE flags of the same name)
+any_module() {
+	local m modules=" $@ "
+
+	for m in ${modules}; do
+		! use $m && modules=${modules/ $m / }
+	done
+
+	shopt -s extglob
+	modules=${modules%%+( )}
+	shopt -u extglob
+
+	[[ ${modules} ]]
+}
+
+# Removes module from modules.d.
+# $1 = module name
+# Module name can be specified without number prefix.
+rm_module() {
+	local m
+
+	for m in $@; do
+		if [[ $m =~ ^[0-9][0-9][^\ ]*$ ]]; then
+			rm -rf "${modules_dir}"/$m
+		else
+			rm -rf "${modules_dir}"/[0-9][0-9]$m
+		fi
+	done
+}
+
+# Displays Gentoo Base System major release number
+base_sys_maj_ver() {
+	local line
+
+	read line < /etc/gentoo-release
+	line=${line##* }
+	echo "${line%%.*}"
+}
+
+#
+# ebuild functions
+#
+
+src_prepare() {
+	epatch "${FILESDIR}/${P}-multipath-udev-rules.patch"
+}
+
+src_compile() {
+	emake WITH_SWITCH_ROOT=0 || die "emake failed"
+}
+
+src_install() {
+	emake WITH_SWITCH_ROOT=0 \
+		prefix=/usr sysconfdir=/etc DESTDIR="${D}" \
+		install || die "emake install failed"
+
+	local gen2conf
+
+	dodir /var/lib/dracut/overlay
+	dodoc HACKING TODO AUTHORS NEWS README* || die 'dodoc failed'
+
+	case "$(base_sys_maj_ver)" in
+		1) gen2conf=gentoo.conf ;;
+		2) gen2conf=gentoo-openrc.conf ;;
+		*) die "Expected ver. 1 or 2 of Gentoo Base System (/etc/gentoo-release)."
+	esac
+
+	insinto /etc/dracut.conf.d
+	newins dracut.conf.d/${gen2conf}.example ${gen2conf} \
+		|| die 'gen2conf ins failed'
+
+	insinto /etc/logrotate.d
+	newins dracut.logrotate dracut || die 'dracut.logrotate ins failed'
+
+	#
+	# Modules
+	#
+	local module
+	modules_dir="${D}/usr/share/dracut/modules.d"
+
+	echo "${PF}" > "${modules_dir}"/10rpmversion/dracut-version \
+		|| die 'dracut-version failed'
+
+	# Remove modules not enabled by USE flags
+	for module in ${IUSE_DRACUT_MODULES} ; do
+		! use ${module} && rm_module ${module#dracut_modules_}
+	done
+
+	# Those flags are specific, and even are corresponding to modules, they need
+	# to be declared as regular USE flags.
+	use debug || rm_module 95debug
+	use selinux || rm_module 98selinux
+
+	! any_module ${DM_MODULES} && rm_module 90dm
+	! any_module ${NETWORK_MODULES} && rm_module 45ifcfg 40network
+
+	# Remove S/390 modules which are not tested at all
+	rm_module 95dasd 95dasd_mod 95zfcp 95znet
+
+	# Remove modules which won't work for sure
+	rm_module 00bootchart 05busybox # broken
+	rm_module 95fcoe # no tools
+
+	# fips module depends on masked app-crypt/hmaccalc
+	rm_module 01fips
+}
+
+pkg_postinst() {
+	elog 'To generate the initramfs:'
+	elog '    # mount /boot (if necessary)'
+	elog '    # dracut "" <kernel-version>'
+	elog ''
+	elog 'For command line documentation see dracut.kernel(7).'
+	elog ''
+	elog 'Simple example to select root and resume partition:'
+	elog '    root=/dev/sda1 resume=/dev/sda2'
+	elog ''
+	elog 'The default config (in /etc/dracut.conf) is very minimal and is highly'
+	elog 'recommended you adjust based on your needs. To include only dracut'
+	elog 'modules and kernel drivers for this system, use the "-H" option.'
+	elog 'Some modules need to be explicitly added with "-a" option even if'
+	elog 'required tools are installed.'
+	echo
+	elog 'Options (documented in dracut.kernel(7)) have new format since'
+	elog 'version 008. Old format is preserved, but will be removed in future.'
+	elog 'Please migrate to the new one.'
+}
diff --git a/sys-kernel/dracut/files/dracut-011-multipath-udev-rules.patch b/sys-kernel/dracut/files/dracut-011-multipath-udev-rules.patch
new file mode 100644
index 000000000000..2b9cffad38c4
--- /dev/null
+++ b/sys-kernel/dracut/files/dracut-011-multipath-udev-rules.patch
@@ -0,0 +1,24 @@
+From 7f3e0c13f1c10e93c3823b6367f9ac83865f3d90 Mon Sep 17 00:00:00 2001
+From: =?UTF-8?q?Amadeusz=20=C5=BBo=C5=82nowski?= <aidecoe@aidecoe.name>
+Date: Fri, 25 Feb 2011 01:44:25 +0100
+Subject: [PATCH] 90multipath: added kpartx.rules; multipath.rules - different prefix
+
+---
+ modules.d/90multipath/module-setup.sh |    2 +-
+ 1 files changed, 1 insertions(+), 1 deletions(-)
+
+diff --git a/modules.d/90multipath/module-setup.sh b/modules.d/90multipath/module-setup.sh
+index f78517c..3f4f612 100755
+--- a/modules.d/90multipath/module-setup.sh
++++ b/modules.d/90multipath/module-setup.sh
+@@ -58,6 +58,6 @@ install() {
+ 
+     inst_hook pre-trigger 02 "$moddir/multipathd.sh"
+     inst_hook pre-pivot   02 "$moddir/multipathd-stop.sh"
+-    inst_rules 40-multipath.rules
++    inst_rules 40-multipath.rules 65-multipath.rules 66-kpartx.rules
+ }
+ 
+-- 
+1.7.4.1
+