http://my.opera.com/desktopteam/blog/2011/06/20/presto-2-9

Package-Manager: portage-2.2.0_alpha41/cvs/Linux i686

3 files changed, 247 insertions, 5 deletions

diff --git a/www-client/opera-next/ChangeLog b/www-client/opera-next/ChangeLog
index d7c3db77cd93..3f1e5daabe39 100644
--- a/www-client/opera-next/ChangeLog
+++ b/www-client/opera-next/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for www-client/opera-next
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/opera-next/ChangeLog,v 1.18 2011/06/14 14:36:44 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/opera-next/ChangeLog,v 1.19 2011/06/20 20:01:25 jer Exp $
+
+*opera-next-11.50.1049 (20 Jun 2011)
+
+  20 Jun 2011; Jeroen Roovers <jer@gentoo.org> +opera-next-11.50.1049.ebuild:
+  http://my.opera.com/desktopteam/blog/2011/06/20/presto-2-9
 
 *opera-next-11.50.1040 (14 Jun 2011)
 
diff --git a/www-client/opera-next/Manifest b/www-client/opera-next/Manifest
index 930811fe3292..c41b033cdd4b 100644
--- a/www-client/opera-next/Manifest
+++ b/www-client/opera-next/Manifest
@@ -37,6 +37,9 @@ DIST opera-next-11.50-1037.x86_64.linux.tar.xz 11602112 RMD160 0eb5c609980e476eb
 DIST opera-next-11.50-1040.i386.freebsd.tar.xz 10898412 RMD160 97021581147f92782b1941822131a5e605ab4691 SHA1 d8cec3946072a771e202a5faa6107bd19c1eacd6 SHA256 98c8fa38ceba6df346b366c11bbf4e4f72447a68249300665035a2f761e2141f
 DIST opera-next-11.50-1040.i386.linux.tar.xz 10854664 RMD160 1f2fbc39bb55b613a9184ee36d231137e6ea7f5b SHA1 4512cdb98ad508d617bdda8cfb6d21d195e92378 SHA256 f56ce226a9f2bf9a1dcc02d888190a2f25b72c933209812b80e333d2cb0b570c
 DIST opera-next-11.50-1040.x86_64.linux.tar.xz 11622036 RMD160 7af220b7bdd0db3522ecc5c1437bcab5ab388b54 SHA1 bc61cb853c7f89bfd3e9db2012145d769286c048 SHA256 520cfbe1cc13b11b89323af735097a7929bcf5c26536da209b396b1e37e41622
+DIST opera-next-11.50-1049.i386.freebsd.tar.xz 10875852 RMD160 44a76425931b812a1ae6771fa662bff80d2d8445 SHA1 33858e4d6fa4afed0a548f4bffd2f29cdbb851db SHA256 306a371e5ffb46a2ea0e7b7e90dfc399df4f016063b19eae8a8c67be20b4365c
+DIST opera-next-11.50-1049.i386.linux.tar.xz 10836812 RMD160 2ca619668ced7f9f22c56a63ebc1dff110a767dc SHA1 c67377f038ddc9d15fa15c38a2c627ef1c594b67 SHA256 0aa06a774b5d32669f8185b74759141c5b824b45c8e8cd72e6c35a7aac160617
+DIST opera-next-11.50-1049.x86_64.linux.tar.xz 11600224 RMD160 a461aee3ad557228fe987139a31412f0db105a4f SHA1 f7dd16349e2b1a28b4e2d862dd14007f3d77a6a6 SHA256 9aed85a6d7de7f680f4ecfed29cb236edfb9793233df243882629ad43eceeb6c
 EBUILD opera-next-11.50.1009.ebuild 5938 RMD160 88b7c94fb996540e5a211fcf2ce278ac2dff6cc8 SHA1 e8b73ada5b8ce747ef697229b6cca2b3d67052d8 SHA256 68106e4e0a47620e1ca868822efcc9ae717cc6663fb30a9e830662fa1ebee498
 EBUILD opera-next-11.50.1015.ebuild 5946 RMD160 8da970b0a9d46985bb7ec456b3f327d2bef98f77 SHA1 1c7c770600862cd83f8b80837b857314c4f5390c SHA256 97cddad9846cf6e75202a619c0072df215f46d4d5b403c7af0ad8ff4c66d5964
 EBUILD opera-next-11.50.1016.ebuild 5947 RMD160 fa066a659b2b0d2fdbb9afb8dda8742f3717ce44 SHA1 6fee78bed4ca2a75d12fa9c3386fa8fadc083d7e SHA256 22708e79fa8c6b392b7919253a6f2a31a8a468c6a9277dd81672c668bede3035
@@ -49,12 +52,13 @@ EBUILD opera-next-11.50.1035.ebuild 6195 RMD160 d039a248078cb351911758f8facac0d9
 EBUILD opera-next-11.50.1036.ebuild 6198 RMD160 88771dc59bb940fdb2434a99b75b1a2ddc68b268 SHA1 340f2ea00e06caef3a6204e7f9ba0e1e6b0b300d SHA256 db7d99ad71dd7f8bd657df81c9d09c618af01597145480a7cf767ac340d0959c
 EBUILD opera-next-11.50.1037.ebuild 6193 RMD160 39ef9c3bdd07e147091ad72df395a09f7df03b34 SHA1 1a9f7e9409687b7fc25e68b64a1b4c27b910c933 SHA256 5d778bd48b461b7b58a4dc6a426abfc373a7beade43b0ba562932f3368cbbfab
 EBUILD opera-next-11.50.1040.ebuild 6193 RMD160 a39db1ced78e4af17b0fa9d902b08db8b94bb514 SHA1 b1e8677a37071d5c066c7dcbe9110041dcd6c942 SHA256 ec9ec509c2628ae7e556ce036cc756945967aa2f9e3b6855b6babacb0b1404d5
-MISC ChangeLog 3327 RMD160 e8ed3d93d1fe5d7d20bb0037b8b49461410c2e99 SHA1 32defa71a6935047d1b70c34c5026719de8ab21c SHA256 b08e0251188c929a1ba0136428d9b10d79327d110db8a798f0e857f1d4d213b4
+EBUILD opera-next-11.50.1049.ebuild 6193 RMD160 e21f1813e3fb8491d7094ca0bc5998be1b09b388 SHA1 83e8b8742542aaaf225d5dc154acabd439364ce9 SHA256 3125ad6e8ae24118ad3408ca86f62298592769aa92484d75ac652d94e63de424
+MISC ChangeLog 3505 RMD160 1d8acde2ed5949d99c739410d12feb7f95cf0b3d SHA1 8354f4c38826f5f441be05222d42cbd60d3cb347 SHA256 6bea13c7083b62de1469eb737dc3d5652687e78a412c25f0ff03c5f7408e206a
 MISC metadata.xml 1547 RMD160 465d146bcfdb6553f7f0ab2dddd68c4dcb2e7731 SHA1 1afb7e0ccc0833ba0eb73be38b282b66ad629ff6 SHA256 5cfc6e7cbf3c454d563eb407b4569f0f5a9b3ce7770026d6055f27211d481915
 -----BEGIN PGP SIGNATURE-----
 Version: GnuPG v2.0.17 (GNU/Linux)
 
-iEYEARECAAYFAk33cg8ACgkQVWmRsqeSphMixQCfSTpORd1Va82YQYcvCzYqJhhN
-Gr8An3bZmdIABpDjwu/9zVI9UT0dIB8L
-=40g3
+iEYEARECAAYFAk3/pTgACgkQVWmRsqeSphNNVQCeLp87tecx7bmq48prdTYdUK94
+phEAn3Q3stc7NjoyHawxgavZR+VrO9Nw
+=dsuT
 -----END PGP SIGNATURE-----
diff --git a/www-client/opera-next/opera-next-11.50.1049.ebuild b/www-client/opera-next/opera-next-11.50.1049.ebuild
new file mode 100644
index 000000000000..e9fec003e487
--- /dev/null
+++ b/www-client/opera-next/opera-next-11.50.1049.ebuild
@@ -0,0 +1,233 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/www-client/opera-next/opera-next-11.50.1049.ebuild,v 1.1 2011/06/20 20:01:25 jer Exp $
+
+EAPI="3"
+
+inherit eutils fdo-mime gnome2-utils multilib pax-utils versionator
+
+DESCRIPTION="A fast and secure web browser and Internet suite"
+HOMEPAGE="http://www.opera.com/"
+
+SLOT="0"
+LICENSE="OPERA-11 LGPL-2 LGPL-3"
+KEYWORDS="~amd64 ~x86 ~x86-fbsd"
+IUSE="elibc_FreeBSD gtk kde +gstreamer"
+
+O_V="$(get_version_component_range 1-2)" # Major version, i.e. 11.00
+O_B="$(get_version_component_range 3)"   # Build version, i.e. 1156
+
+O_D="2854_${O_V}-${O_B}"
+O_P="${PN}-${O_V}-${O_B}"
+O_U="http://snapshot.opera.com/unix/"
+
+SRC_URI="
+	amd64? ( ${O_U}${O_D}/${O_P}.x86_64.linux.tar.xz )
+	x86? ( ${O_U}${O_D}/${O_P}.i386.linux.tar.xz )
+	x86-fbsd? ( ${O_U}${O_D}/${O_P}.i386.freebsd.tar.xz )
+"
+
+OPREFIX="/usr/$(get_libdir)"
+
+QA_DT_HASH="${OPREFIX}/${PN}/.*"
+QA_PRESTRIPPED="${OPREFIX}/${PN}/.*"
+
+O_LINGUAS="
+	af az be bg cs da de el en-GB es-ES es-LA et fi fr fr-CA fy gd hi hr hu id
+	it ja ka ko lt me mk ms nb nl nn pl pt pt-BR ro ru sk sr sv ta te th tl tr
+	uk uz vi zh-CN zh-TW
+"
+
+for O_LINGUA in ${O_LINGUAS}; do
+	IUSE="${IUSE} linguas_${O_LINGUA/-/_}"
+done
+
+DEPEND="
+	>=sys-apps/sed-4
+	app-arch/xz-utils
+"
+GTKRDEPEND="
+	dev-libs/atk
+	dev-libs/glib:2
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:2
+	x11-libs/pango
+	x11-libs/pixman
+"
+KDERDEPEND="
+	kde-base/kdelibs
+	x11-libs/qt-core
+	x11-libs/qt-gui
+"
+GSTRDEPEND="
+	dev-libs/glib
+	dev-libs/libxml2
+	media-plugins/gst-plugins-meta
+	media-libs/gstreamer
+"
+RDEPEND="
+	media-libs/fontconfig
+	media-libs/freetype
+	sys-apps/util-linux
+	sys-libs/zlib
+	virtual/opengl
+	x11-libs/libICE
+	x11-libs/libSM
+	x11-libs/libX11
+	x11-libs/libXext
+	x11-libs/libXft
+	x11-libs/libXrender
+	gtk? ( ${GTKRDEPEND} )
+	kde? ( ${KDERDEPEND} )
+	gstreamer? ( ${GSTRDEPEND} )
+"
+
+pkg_setup() {
+	echo -e \
+		" ${GOOD}****************************************************${NORMAL}"
+	elog "If you seek support, please file a bug report at"
+	elog "https://bugs.gentoo.org and post the output of"
+	elog " \`emerge --info =${CATEGORY}/${P}'"
+	echo -e \
+		" ${GOOD}****************************************************${NORMAL}"
+}
+
+src_unpack() {
+	unpack ${A}
+	mv -v ${PN}* "${S}" || die
+}
+
+src_prepare() {
+	local LNGDIR="share/${PN}/locale"
+
+	# Count linguas
+	count() { echo ${#}; }
+	local lingua_count=$(count ${O_LINGUAS} en)
+	local locale_count=$(count ${LNGDIR}/*)
+	[[ ${lingua_count} = ${locale_count} ]] \
+		|| die "Number of LINGUAS does not match number of locales"
+	unset count
+
+	# Remove unwanted linguas
+	einfo "Keeping these locales (linguas): ${LINGUAS}."
+	for LINGUA in ${O_LINGUAS}; do
+		if ! use linguas_${LINGUA/-/_}; then
+			LINGUA=$(find "${LNGDIR}" -maxdepth 1 -type d -iname ${LINGUA/_/-})
+			rm -r "${LINGUA}" || die "The list of linguas needs to be fixed"
+		fi
+	done
+
+	# Remove doc directory but keep the LICENSE under another name (bug #315473)
+	mv share/doc/${PN}/LICENSE share/${PN}/defaults/license.txt
+	rm -rf share/doc
+	for locale in share/${PN}/locale/*; do
+		rm -f "${locale}/license.txt"
+		ln -sn /usr/share/${PN}/defaults/license.txt "${locale}/license.txt" \
+			|| die "ln -sn license.txt"
+	done
+
+	# Remove package directory
+	rm -rf share/${PN}/package
+
+	# Leave libopera*.so only if the user chooses
+	if ! use gtk; then
+		rm lib/${PN}/liboperagtk.so || die "rm liboperagtk.so failed"
+	fi
+	if ! use kde; then
+		rm lib/${PN}/liboperakde4.so || die "rm liboperakde4.so failed"
+	fi
+
+	# Unzip the man pages before sedding
+	gunzip share/man/man1/* || die "gunzip failed"
+
+	# Replace PREFIX, SUFFIX and PN in various files
+	sed -i \
+		-e "s:@@{PREFIX}:/usr:g" \
+		-e "s:@@{SUFFIX}::g" \
+		-e "s:@@{_SUFFIX}::g" \
+		-e "s:@@{USUFFIX}::g" \
+		-e "s:opera:${PN}:g" \
+		share/man/man1/* \
+		share/applications/${PN}-browser.desktop \
+		|| die "sed failed"
+
+	# Create /usr/bin/opera wrapper
+	echo '#!/bin/sh' > ${PN}
+	echo 'export OPERA_DIR=/usr/share/'"${PN}" >> ${PN}
+	echo 'export OPERA_PERSONALDIR=${OPERA_PERSONALDIR:-"${HOME}/.'${PN}'"}' \
+		>> ${PN}
+	echo 'exec '"${OPREFIX}/${PN}/${PN}"' "$@"' >> ${PN}
+
+	# Fix libdir in defaults/pluginpath.ini
+	sed -i \
+		share/${PN}/defaults/pluginpath.ini \
+		-e "s|/usr/lib32|${OPREFIX}|g" \
+		-e '/netscape/{s|[0-1]|2|g}' \
+		|| die "sed pluginpath.ini failed"
+
+	# Change libz.so.3 to libz.so.1 for gentoo/freebsd
+	if use elibc_FreeBSD; then
+		scanelf -qR -N libz.so.3 -F "#N" lib/${PN}/ | \
+		while read i; do
+			if [[ $(strings "$i" | fgrep -c libz.so.3) -ne 1 ]];
+			then
+				export SANITY_CHECK_LIBZ_FAILED=1
+				break
+			fi
+			sed -i \
+				"$i" \
+				-e 's/libz\.so\.3/libz.so.1/g'
+		done
+		[[ "$SANITY_CHECK_LIBZ_FAILED" = "1" ]] \
+			&& die "failed to change libz.so.3 to libz.so.1"
+	fi
+}
+
+src_install() {
+	# We install into usr instead of opt as Opera does not support the latter
+	dodir /usr
+	mv lib/ "${D}/${OPREFIX}" || die "mv lib/ failed"
+	mv share/ "${D}/usr/" || die "mv share/ failed"
+
+	# Install startup scripts
+	dobin ${PN} || die "dobin failed"
+
+	# Stop revdep-rebuild from checking opera binaries
+	dodir /etc/revdep-rebuild
+	echo "SEARCH_DIRS_MASK=\"${OPREFIX}/${PN}\"" \
+		> "${D}"/etc/revdep-rebuild/90${PN}
+
+	# Set PaX markings for hardened/PaX (bug #344267)
+	pax-mark m \
+		"${D}/${OPREFIX}/${PN}/${PN}" \
+		"${D}/${OPREFIX}/${PN}/operaplugincleaner" \
+		"${D}/${OPREFIX}/${PN}/operapluginwrapper"
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	elog "To change the UI language, choose [Tools] -> [Preferences], open the"
+	elog "[General] tab, click on [Details...] then [Choose...] and point the"
+	elog "file chooser at /usr/share/${PN}/locale/, then enter the"
+	elog "directory for the language you want and [Open] the .lng file."
+
+	if use elibc_FreeBSD; then
+		elog
+		elog "To improve shared memory usage please set:"
+		elog "$ sysctl kern.ipc.shm_allow_removed=1"
+	fi
+
+	# Update desktop file database and gtk icon cache (bug #334993)
+	gnome2_icon_cache_update
+	fdo-mime_desktop_database_update
+}
+
+pkg_postrm() {
+	# Update desktop file database and gtk icon cache (bug #334993)
+	gnome2_icon_cache_update
+	fdo-mime_desktop_database_update
+}