Backport upstream patch to include Chromium (or Google Chrome) in the preferred browsers list wrt #388853 by Michael Mol and Paweł Hajdan, Jr.

Package-Manager: portage-2.2.0_alpha89/cvs/Linux x86_64

1 files changed, 64 insertions, 0 deletions

diff --git a/xfce-base/exo/exo-0.6.2-r1.ebuild b/xfce-base/exo/exo-0.6.2-r1.ebuild
new file mode 100644
index 000000000000..166113c2bc93
--- /dev/null
+++ b/xfce-base/exo/exo-0.6.2-r1.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/xfce-base/exo/exo-0.6.2-r1.ebuild,v 1.1 2012/03/01 15:10:21 ssuominen Exp $
+
+EAPI=4
+PYTHON_DEPEND="python? 2:2.6"
+EAUTORECONF=yes
+inherit python xfconf
+
+DESCRIPTION="Extensions, widgets and framework library with session management support"
+HOMEPAGE="http://www.xfce.org/projects/exo/"
+SRC_URI="mirror://xfce/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2 LGPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~x64-solaris ~x86-solaris"
+IUSE="debug python"
+
+RDEPEND=">=dev-lang/perl-5.6
+	>=dev-libs/glib-2.18
+	dev-perl/URI
+	>=x11-libs/gtk+-2.14:2
+	>=xfce-base/libxfce4util-4.8
+	python? ( >=dev-python/pygtk-2.4 )"
+DEPEND="${RDEPEND}
+	dev-util/intltool
+	dev-util/pkgconfig
+	sys-devel/gettext"
+
+pkg_setup() {
+	if use python; then
+		python_set_active_version 2
+		python_pkg_setup
+	fi
+
+	PATCHES=( "${FILESDIR}"/${PN}-0.6.x-chromium.patch )
+
+	XFCONF=(
+		--docdir="${EPREFIX}"/usr/share/doc/${PF}
+		--disable-static
+		$(use_enable python)
+		$(xfconf_use_debug)
+		--with-html-dir="${EPREFIX}"/usr/share/doc/${PF}/html
+		)
+
+	[[ ${CHOST} == *-darwin* ]] && XFCONF+=( --disable-visibility ) #366857
+
+	DOCS=( AUTHORS ChangeLog HACKING NEWS README THANKS TODO )
+}
+
+src_prepare() {
+	>py-compile
+	xfconf_src_prepare
+}
+
+pkg_postinst() {
+	xfconf_pkg_postinst
+	use python && python_mod_optimize exo-0.6 pyexo.py
+}
+
+pkg_postrm() {
+	xfconf_pkg_postrm
+	use python && python_mod_cleanup exo-0.6 pyexo.py
+}