1 files changed, 45 insertions, 0 deletions
diff --git a/media-libs/libmng/libmng-1.0.10-r1.ebuild b/media-libs/libmng/libmng-1.0.10-r1.ebuild
new file mode 100644
index 000000000000..9e4e1dabb4ed
--- /dev/null
+++ b/media-libs/libmng/libmng-1.0.10-r1.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libmng/libmng-1.0.10-r1.ebuild,v 1.1 2011/02/19 18:25:26 ssuominen Exp $
+
+EAPI=3
+inherit autotools
+
+DESCRIPTION="Multiple Image Networkgraphics lib (animated png's)"
+HOMEPAGE="http://www.libmng.com/"
+SRC_URI="mirror://sourceforge/libmng/${P}.tar.gz"
+
+LICENSE="as-is"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="lcms static-libs"
+
+RDEPEND="virtual/jpeg
+	>=sys-libs/zlib-1.1.4
+	lcms? ( =media-libs/lcms-1* )"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	ln -s makefiles/configure.in .
+	ln -s makefiles/Makefile.am .
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--disable-dependency-tracking \
+		$(use_enable static-libs static) \
+		--with-jpeg \
+		$(use_with lcms)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die
+
+	find "${ED}" -name '*.la' -exec rm -f {} +
+
+	dodoc CHANGES README*
+	dodoc doc/doc.readme doc/libmng.txt
+	doman doc/man/*
+}