1 files changed, 38 insertions, 0 deletions
diff --git a/sys-apps/hdparm/hdparm-9.39.ebuild b/sys-apps/hdparm/hdparm-9.39.ebuild
new file mode 100644
index 000000000000..ebc42451837a
--- /dev/null
+++ b/sys-apps/hdparm/hdparm-9.39.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/hdparm/hdparm-9.39.ebuild,v 1.1 2012/02/04 17:41:32 radhermit Exp $
+
+EAPI="4"
+
+inherit toolchain-funcs
+
+DESCRIPTION="Utility to change hard drive performance parameters"
+HOMEPAGE="http://sourceforge.net/projects/hdparm/"
+SRC_URI="mirror://sourceforge/hdparm/${P}.tar.gz"
+
+LICENSE="as-is"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-linux"
+IUSE=""
+
+src_prepare() {
+	sed -i \
+		-e "/^CFLAGS/ s:-O2:${CFLAGS}:" \
+		-e "/^LDFLAGS/ s:-s:${LDFLAGS}:" \
+		Makefile || die "sed"
+}
+
+src_compile() {
+	emake STRIP=: CC="$(tc-getCC)"
+}
+
+src_install() {
+	into /
+	dosbin hdparm contrib/idectl
+
+	newinitd "${FILESDIR}"/hdparm-init-8 hdparm
+	newconfd "${FILESDIR}"/hdparm-conf.d.3 hdparm
+
+	doman hdparm.8
+	dodoc hdparm.lsm Changelog README.acoustic hdparm-sysconfig
+}