blob: 50ac1a5962fc523712657ed247d816abe5e5d07d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
|
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-arch/file-roller/file-roller-3.6.2.ebuild,v 1.2 2012/12/31 14:14:57 ago Exp $
EAPI="5"
GCONF_DEBUG="no"
GNOME2_LA_PUNT="yes"
inherit eutils gnome2
DESCRIPTION="Archive manager for GNOME"
HOMEPAGE="http://fileroller.sourceforge.net/"
LICENSE="GPL-2+ CCPL-Attribution-ShareAlike-3.0"
SLOT="0"
IUSE="nautilus packagekit"
KEYWORDS="~amd64 ~ppc ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux"
# gdk-pixbuf used extensively in the source
# cairo used in eggtreemultidnd.c
# pango used in fr-window
RDEPEND=">=dev-libs/glib-2.29.14:2
sys-apps/file
x11-libs/cairo
x11-libs/gdk-pixbuf:2
x11-libs/pango
x11-libs/libSM
x11-libs/libICE
>=x11-libs/gtk+-3.4.0:3
>=app-arch/libarchive-3.0.0:=
>=x11-libs/libnotify-0.4.3:=
>=dev-libs/json-glib-0.14.0
nautilus? ( >=gnome-base/nautilus-3 )
packagekit? ( app-admin/packagekit-base )
"
DEPEND="${RDEPEND}
>=dev-util/intltool-0.40.0
sys-devel/gettext
virtual/pkgconfig"
# eautoreconf needs:
# gnome-base/gnome-common
src_prepare() {
# --disable-debug because enabling it adds -O0 to CFLAGS
G2CONF="${G2CONF}
--disable-dependency-tracking
--disable-run-in-place
--disable-static
--disable-debug
--enable-magic
--enable-libarchive
--with-smclient=xsmp
$(use_enable nautilus nautilus-actions)
$(use_enable packagekit)
ITSTOOL=$(type -P true)"
DOCS="AUTHORS ChangeLog HACKING MAINTAINERS NEWS README TODO"
gnome2_src_prepare
# Use absolute path to GNU tar since star doesn't have the same
# options. On Gentoo, star is /usr/bin/tar, GNU tar is /bin/tar
epatch "${FILESDIR}"/${PN}-2.10.3-use_bin_tar.patch
# File providing Gentoo package names for various archivers
cp -f "${FILESDIR}/3.6.0-packages.match" data/packages.match || die
}
pkg_postinst() {
gnome2_pkg_postinst
elog "${PN} is a frontend for several archiving utilities. If you want a"
elog "particular achive format support, see ${HOMEPAGE}"
elog "and install the relevant package."
elog
elog "for example:"
elog " 7-zip - app-arch/p7zip"
elog " ace - app-arch/unace"
elog " arj - app-arch/arj"
elog " cpio - app-arch/cpio"
elog " deb - app-arch/dpkg"
elog " iso - app-cdr/cdrtools"
elog " jar,zip - app-arch/zip and app-arch/unzip"
elog " lha - app-arch/lha"
elog " lzop - app-arch/lzop"
elog " rar - app-arch/unrar or app-arch/unar"
elog " rpm - app-arch/rpm"
elog " unstuff - app-arch/stuffit"
elog " zoo - app-arch/zoo"
}
|
GitWeb