blob: 12baaa748a4e9a447caa2266f6d98e3970f54032 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
|
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-misc/g15daemon/g15daemon-1.9.5.3-r5.ebuild,v 1.1 2011/09/09 15:19:23 scarabeus Exp $
EAPI=3
GENTOO_DEPEND_ON_PERL="no"
PYTHON_DEPEND="python? *"
SUPPORT_PYTHON_ABIS="1"
inherit eutils linux-info perl-module python base
DESCRIPTION="G15daemon takes control of the G15 keyboard, through the linux kernel uinput device driver"
HOMEPAGE="http://g15daemon.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE="perl python"
DEPEND="virtual/libusb:0
>=dev-libs/libg15-1.2.4
>=dev-libs/libg15render-1.2
perl? (
dev-lang/perl
dev-perl/GDGraph
>=dev-perl/Inline-0.4
)"
RDEPEND="${DEPEND}"
PATCHES=(
"${FILESDIR}/${P}-forgotten-open-mode.patch"
"${FILESDIR}/${P}-overflow-fix.patch"
)
uinput_check() {
ebegin "Checking for uinput support"
local rc=1
linux_config_exists && linux_chkconfig_present INPUT_UINPUT
rc=$?
if [[ $rc -ne 0 ]] ; then
eerror "To use g15daemon, you need to compile your kernel with uinput support."
eerror "Please enable uinput support in your kernel config, found at:"
eerror
eerror "Device Drivers -> Input Device ... -> Miscellaneous devices -> User level driver support."
eerror
eerror "Once enabled, you should have the /dev/input/uinput device."
eerror "g15daemon will not work without the uinput device."
fi
}
pkg_setup() {
linux-info_pkg_setup
uinput_check
if use python; then
python_pkg_setup
fi
}
src_unpack() {
unpack ${A}
if use perl; then
unpack "./${P}/lang-bindings/perl-G15Daemon-0.2.tar.gz"
fi
if use python; then
unpack "./${P}/lang-bindings/pyg15daemon-0.0.tar.bz2"
fi
}
src_prepare() {
if use perl; then
perl-module_src_prepare
sed -i \
-e '1i#!/usr/bin/perl' \
"${S}"/contrib/testbindings.pl
else
# perl-module_src_prepare always calls base_src_prepare
base_src_prepare
fi
}
src_configure() {
econf \
--disable-static
if use perl; then
cd "${WORKDIR}/G15Daemon-0.2"
perl-module_src_configure
fi
}
src_compile() {
emake || die
if use perl; then
cd "${WORKDIR}/G15Daemon-0.2"
perl-module_src_compile
fi
}
src_install() {
emake DESTDIR="${D}" \
docdir=/usr/share/doc/${PF} install || die "make install failed"
find "${ED}" -name '*.la' -exec rm -f {} +
# remove odd docs installed my make
rm "${D}/usr/share/doc/${PF}/"{LICENSE,README.usage}
insinto /usr/share/${PN}/contrib
doins contrib/xmodmaprc
doins contrib/xmodmap.sh
if use perl; then
doins contrib/testbindings.pl
fi
newconfd "${FILESDIR}/${PN}-1.2.7.confd" ${PN}
newinitd "${FILESDIR}/${PN}-1.2.7-r2.initd" ${PN}
dobin "${FILESDIR}/g15daemon-hotplug"
insinto /lib/udev/rules.d
doins "${FILESDIR}/99-g15daemon.rules"
insinto /etc
doins "${FILESDIR}"/g15daemon.conf
# Gentoo bug #301340, debian bug #611649
exeinto /usr/lib/pm-utils/sleep.d
doexe "${FILESDIR}"/20g15daemon
if use perl; then
ebegin "Installing Perl Bindings (G15Daemon.pm)"
cd "${WORKDIR}/G15Daemon-0.2"
docinto perl
perl-module_src_install
fi
if use python; then
ebegin "Installing Python Bindings (g15daemon.py)"
cd "${WORKDIR}/pyg15daemon"
installation() {
insinto $(python_get_sitedir)
doins g15daemon.py
}
python_execute_function installation
docinto python
dodoc AUTHORS
fi
}
pkg_postinst() {
if use python; then
python_mod_optimize g15daemon.py
echo ""
fi
elog "To use g15daemon, you need to add g15daemon to the default runlevel."
elog "This can be done with:"
elog "# /sbin/rc-update add g15daemon default"
elog "You can edit some g15daemon options at /etc/conf.d/g15daemon"
elog ""
elog "To have all new keys working in X11, you'll need create a "
elog "specific xmodmap in your home directory or edit the existent one."
elog ""
elog "Create the xmodmap:"
elog "cp /usr/share/g15daemon/contrib/xmodmaprc ~/.Xmodmap"
elog ""
elog "Adding keycodes to an existing xmodmap:"
elog "cat /usr/share/g15daemon/contrib/xmodmaprc >> ~/.Xmodmap"
}
pkg_postrm() {
if use python; then
python_mod_cleanup g15daemon.py
fi
}
|
GitWeb