dev-libs/libindicate/libindicate-0.2.3.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/libindicate/libindicate-0.2.3.ebuild,v 1.4 2009/11/23 22:34:22 mrpouet Exp $

EAPI=2

inherit autotools eutils versionator

DESCRIPTION="Library to raise flags on DBus for other components of the desktop to pick up and visualize"
HOMEPAGE="https://launchpad.net/libindicate/"
SRC_URI="http://launchpad.net/${PN}/$(get_version_component_range 1-2)/${PV}/+download/${P}.tar.gz"

LICENSE="LGPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="gtk doc"
# They put their mother in the tarball ? ^^
RESTRICT="test"

RDEPEND="dev-libs/glib:2
	>=dev-libs/dbus-glib-0.76
	dev-libs/libxml2:2
	gtk? ( x11-libs/gtk+:2 )"
DEPEND="${RDEPEND}
	doc? ( dev-util/gtk-doc )
	dev-util/pkgconfig"
src_prepare() {
	# Make libindicator-gtk library optional
	epatch "${FILESDIR}/${P}-optional-gtk-support.patch"
	# Drop -Werror in a release
	sed -e 's:-Werror::g' -i libindicate/Makefile.in || die "sed failed"
	eautoreconf
}
src_configure() {
	local my_conf

	# gobject-instrospection is a nightmare in this package, it's fixable for libindicate
	# and not for libindicate-gtk, disable it until its fixed on upstream
	my_conf="--disable-dependency-tracking
		--disable-gobject-introspection
		$(use_enable gtk)
		$(use_enable doc)"
	# Fix bug 294279
	use doc && my_conf="$my_conf --docdir=/usr/share/doc/${PF}"
	econf $my_conf
}
src_test() {
	emake check || die "testsuite failed"
}
src_install() {
	emake DESTDIR="${D}" install || die "make install failed"
	dodoc AUTHORS || die "dodoc failed"
}