x11-libs/gl2ps/gl2ps-1.3.5-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-libs/gl2ps/gl2ps-1.3.5-r1.ebuild,v 1.2 2010/07/19 08:08:40 ssuominen Exp $

EAPI="3"
inherit cmake-utils multilib

DESCRIPTION="OpenGL to PostScript printing library"
HOMEPAGE="http://www.geuz.org/gl2ps/"
SRC_URI="http://geuz.org/${PN}/src/${P}.tgz"

LICENSE="LGPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
IUSE="doc png zlib"

DEPEND="virtual/glut
	png? ( media-libs/libpng )
	zlib? ( sys-libs/zlib )
	doc? (
		dev-tex/tth
		dev-texlive/texlive-latex
		)"

S=${WORKDIR}/${P}-source

PATCHES=( "${FILESDIR}/${P}-CMakeLists.patch" )

src_configure() {
	mycmakeargs="${mycmakeargs}
		$(cmake-utils_use_has png PNG)
		$(cmake-utils_use_has zlib ZLIB)
		$(cmake-utils_use_has doc DOC)"
	cmake-utils_src_configure
}

src_install() {
	cmake-utils_src_install
	prepalldocs

	if [[ ${CHOST} == *-darwin* ]] ; then
		# CMake produces an invalid dylib here, but I have no clue how to fix it
		# hmm, it's also unversioned :(
		install_name_tool \
			-id "${EPREFIX}"/usr/$(get_libdir)/libgl2ps.dylib \
			"${D%/}${EPREFIX}"/usr/$(get_libdir)/libgl2ps.dylib || die
	fi
}