x11-wm/i3/i3-4.0.2.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63

# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-wm/i3/i3-4.0.2.ebuild,v 1.1 2011/08/28 18:24:02 xarthisius Exp $

EAPI=4

inherit base versionator toolchain-funcs

DESCRIPTION="An improved dynamic tiling window manager"
HOMEPAGE="http://i3wm.org/"
SRC_URI="http://i3wm.org/downloads/${P}.tar.bz2"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

CDEPEND="dev-libs/libev
	dev-libs/yajl
	x11-libs/libxcb
	x11-libs/libX11
	x11-libs/xcb-util"
DEPEND="${CDEPEND}
	app-text/asciidoc
	dev-util/pkgconfig
	sys-devel/flex
	sys-devel/bison
	x11-proto/xcb-proto"
RDEPEND="${CDEPEND}
	dev-perl/AnyEvent-I3
	dev-perl/IPC-Run
	dev-perl/Try-Tiny
	virtual/perl-Getopt-Long
	x11-apps/xmessage"

DOCS=( GOALS TODO RELEASE-NOTES-${PV} )
PATCHES=( "${FILESDIR}"/${PN}-4.0.1-gentoo-r1.diff )

pkg_setup() {
	tc-export CC
	ewarn "${PN} uses x11-terms/rxvt-unicode as a default terminal."
	ewarn "If you wish to use another one merge ${PN} with:"
	ewarn "	TERM_EMU=<YOUR_TERM> emerge ${PN}"
	ewarn "e.g. TERM_EMU=xterm"
}

src_prepare() {
	base_src_prepare
	sed -i -e "/echo \"/d" \
		i3{bar,-config-wizard,-input,-msg,-nagbar}/Makefile || die
}

src_install() {
	base_src_install
	dohtml -r docs/*
	doman i3bar/doc/i3bar.1
}

pkg_postinst() {
	elog "${PN} uses x11-terms/rxvt-unicode as a default terminal."
	elog "Either merge it yourself or change proper bind in"
	elog "/etc/${PN}/config or ~/.${PN}/config"
}