gnome-extra/commit: new package, add 4.1

Signed-off-by: Julien Roy <julien@jroy.ca>

3 files changed, 101 insertions, 0 deletions

diff --git a/gnome-extra/commit/Manifest b/gnome-extra/commit/Manifest
new file mode 100644
index 000000000..81dbce18f
--- /dev/null
+++ b/gnome-extra/commit/Manifest
@@ -0,0 +1,2 @@
+DIST commit-4.1-troll.gh.tar.gz 474880 BLAKE2B 9ebde0b0d32dd0591f1940add827776938d42121b84b391c478ad7baf82580eec12b084c89bf6cebbf34759aea5b6bdc7ced518fa56ea9a9def7bcc5b5a2c734 SHA512 140eeae1458aeed3ce294fb89c4c1ae84a947f3abf6992d1bcaca23e78595f5f41700934889914c1f152fc0d31543205f62097ee000c7f285edf853be79beb13
+DIST commit-4.1.gh.tar.gz 598633 BLAKE2B 8381d385ca62f351cc61e405e115f81311eb6509ab32f75e42e066ed3ab24156b8f6036c94204c5137ab720e976099a6f80a9b1c21145126857076b520367330 SHA512 0208cbea33d19913ca928e72397ffb5cb40456ab1154f0ccd9a271758eb77491f7197a39c9593c5daad207e35f16de8ac05da8c85aced790a4152564f9e77f76
diff --git a/gnome-extra/commit/commit-4.1.ebuild b/gnome-extra/commit/commit-4.1.ebuild
new file mode 100644
index 000000000..3bf78f0dc
--- /dev/null
+++ b/gnome-extra/commit/commit-4.1.ebuild
@@ -0,0 +1,62 @@
+# Copyright 2023-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome2-utils meson xdg
+
+TROLL_COMMIT="e7933a083681d23fce0078b0246fcff244af5ac3"
+DESCRIPTION="Commit message editor"
+HOMEPAGE="
+	https://github.com/sonnyp/Commit
+	https://apps.gnome.org/Commit/
+"
+SRC_URI="
+	https://github.com/sonnyp/Commit/archive/v${PV}.tar.gz -> ${P}.gh.tar.gz
+	https://github.com/sonnyp/troll/archive/${TROLL_COMMIT}.tar.gz -> ${P}-troll.gh.tar.gz
+"
+S="${WORKDIR}/${PN/c/C}-${PV}"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	app-text/libspelling
+	gui-libs/gtk:4
+	gui-libs/libadwaita:1
+"
+DEPEND="${RDEPEND}"
+
+BDEPEND="
+	app-alternatives/ninja
+	dev-libs/appstream-glib
+	dev-libs/gjs
+	dev-libs/glib:2=
+	dev-util/blueprint-compiler
+	dev-util/desktop-file-utils
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+
+src_unpack() {
+	default
+	mv "${WORKDIR}"/troll-${TROLL_COMMIT}/* "${S}"/troll || die
+}
+
+src_install() {
+	meson_src_install
+	dosym -r /usr/bin/re.sonny.Commit /usr/bin/"${PN}"
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+	xdg_icon_cache_update
+}
diff --git a/gnome-extra/commit/metadata.xml b/gnome-extra/commit/metadata.xml
new file mode 100644
index 000000000..94407373e
--- /dev/null
+++ b/gnome-extra/commit/metadata.xml
@@ -0,0 +1,37 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<name>Julien Roy</name>
+		<email>julien@jroy.ca</email>
+	</maintainer>
+	<longdescription>
+Commit is an editor that helps you write better Git and Mercurial commit messages.
+
+After installing make sure to launch the application and follow the instructions.
+
+Commit will pop up automatically when you make a commit in one of your projects. To save your commit message, press the Commit button or the Ctrl+Return shortcut. To abort and dismiss Commit, press the Abort button or the Escape key.
+
+Features:
+
+Highlights overflow of the commit title
+Smart body wrapping
+Inserts a blank line between title and body
+Spell checking
+Comments are read-only and excluded from "Select All"
+Displays project folder and branch in window header
+Dark mode support
+Keyboard navigation and shortcuts
+Undo/Redo support
+Emoji picker
+Supports git commit, merge, tag --annotate, add --patch, rebase --interactive
+Supports Mercurial commit
+Auto capitalize the commit title
+Welcome window with settings and instructions
+Highlight syntax for Git, Mercurial and diffs
+	</longdescription>
+	<upstream>
+		<bugs-to>https://github.com/sonnyp/Commit/issues</bugs-to>
+		<remote-id type="github">sonnyp/Commit</remote-id>
+	</upstream>
+</pkgmetadata>