3 files changed, 157 insertions, 0 deletions
diff --git a/x11-libs/vte/Manifest b/x11-libs/vte/Manifest
index 591a1da..c5a5014 100644
--- a/x11-libs/vte/Manifest
+++ b/x11-libs/vte/Manifest
@@ -2,3 +2,5 @@ DIST vte-0.34.2.tar.xz 981688 SHA256 f40f9fe0bcc6d65bc44b2fab5469b56a9f0631132c6
 DIST vte-0.34.9.tar.xz 996756 SHA256 6f38c5edf57d0a5b870c4e5e210731cccfb4899d0856ba7a3dc599f2ba6e23e1 SHA512 57fff7d5916bcd8a8a13e3cf050f85ed78e9154fdf2510a6d6f594f938c6d56f512089c6bc3e06c9123d35d17f2eb3b3814a5407635027ec0116c25f73034688 WHIRLPOOL 2caf90fdbce7baaf6038c0fda674577724ace354e63b8a6977e46b7f2cea8860f1a687cf34d4e10c4b08eeb666f6c62c42c0f5cfb0c55498fcc44cf44c9570d8
 DIST vte-0.36.2.tar.xz 1009160 SHA256 f45eed3aed823068c7563345ea947be0e6ddb3dacd74646e6d7d26a921e04345 SHA512 fafd368b95918024e6324c81f4fa6c35ad15138ad44af2f92164492d9773b127202d11824c9def4a26e17de44336f42e9c8906330dd300795c280ca068381632 WHIRLPOOL 034b6879131d2535e21a8a97e571753e250f98e01ef334d639038a0638fc0a6d214a267267f11822c30919629edaabc6f6a66a366a9b506ae57e2d4674efa724
 DIST vte-0.36.3.tar.xz 1013412 SHA256 54e5b07be3c0f7b158302f54ee79d4de1cb002f4259b6642b79b1e0e314a959c SHA512 9e0c4e60c5a271720d7b480c9618069752faec6c310cc2477e67cdb1c3e961f6981d39c9116716739390dc8e4bab9bf06cf6c5d7d2546062e48523f85d731c77 WHIRLPOOL 0c582f50a07b9a55e8e7b16ae371b913348e8f93fc50ff734ea04a481a5e1ca30ebf3c3781dcd20fd340f50b34cd8f516de76ca59093f3952f23b99a5b30ddca
+DIST vte-0.36.4.tar.xz 1012848 SHA256 aa549b114c80e18791b57031e5c1714aeb4a104405e3ba78dfd4ac374a71e2a1 SHA512 97bb226abaf2100a21856040039640005809eae647432c03a33eb691c8b0a29c13bd8cf824790c2a6360356c8c5d1b61c48b4a7893c7f0a8d3678b1a0914aa31 WHIRLPOOL d1294540c67e3253b166dc351b68534d9f36b1306449e2a319705cafe0317452e3bbe1768fdc30523f85270c2b949b9d9cf606695989968da4a099355413904c
+DIST vte-0.40.2.tar.xz 923852 SHA256 9b68fbc16b27f2d79e6271f2b0708808594ac5acf979d0fccea118608199fd2d SHA512 06d1c9a34e8e82e1bd54810d245d908ebb837538ba19fbaabe683cdf3b96b7cb1630516ddeabf18b0294922b8d98d2b9a2f5028c171fac2ad913974d94555eb2 WHIRLPOOL 2499e01c2b0d38645b61d4c0a1814d7a3196df6d300577380f1e622c06a974a4cd0d9799fff35f1b0680603aa3a0be38730991ace83df90bfb265009873c5858
diff --git a/x11-libs/vte/vte-0.36.4.ebuild b/x11-libs/vte/vte-0.36.4.ebuild
new file mode 100644
index 0000000..fd92b0d
--- /dev/null
+++ b/x11-libs/vte/vte-0.36.4.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+GCONF_DEBUG="no"
+
+inherit eutils gnome2
+
+DESCRIPTION="Library providing a virtual terminal emulator widget"
+HOMEPAGE="https://wiki.gnome.org/action/show/Apps/Terminal/VTE"
+
+LICENSE="LGPL-2+"
+SLOT="2.90"
+IUSE="debug glade +introspection termite-patch"
+KEYWORDS="~amd64 ~x86"
+
+PDEPEND=">=x11-libs/gnome-pty-helper-${PV}"
+RDEPEND="
+	>=dev-libs/glib-2.31.13:2
+	>=x11-libs/gtk+-3.1.9:3[introspection?]
+	>=x11-libs/pango-1.22.0
+
+	sys-libs/ncurses
+	x11-libs/libX11
+	x11-libs/libXft
+
+	glade? ( >=dev-util/glade-3.9:3.10 )
+	introspection? ( >=dev-libs/gobject-introspection-0.9.0:= )
+"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1.13
+	>=dev-util/intltool-0.35
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	# https://bugzilla.gnome.org/show_bug.cgi?id=663779
+	epatch "${FILESDIR}/${PN}-0.30.1-alt-meta.patch"
+
+	use termite-patch && epatch "${FILESDIR}"/${PN}-0.32.2-expose_select_text.patch
+
+	gnome2_src_prepare
+}
+
+src_configure() {
+	local myconf=""
+
+	if [[ ${CHOST} == *-interix* ]]; then
+		myconf="${myconf} --disable-Bsymbolic"
+
+		# interix stropts.h is empty...
+		export ac_cv_header_stropts_h=no
+	fi
+
+	# Python bindings are via gobject-introspection
+	# Ex: from gi.repository import Vte
+	# Do not disable gnome-pty-helper, bug #401389
+	gnome2_src_configure \
+		--disable-deprecation \
+		--disable-static \
+		$(use_enable debug) \
+		$(use_enable glade glade-catalogue) \
+		$(use_enable introspection) \
+		${myconf}
+}
+
+src_install() {
+	DOCS="AUTHORS ChangeLog HACKING NEWS README"
+	gnome2_src_install
+	rm -v "${ED}usr/libexec/gnome-pty-helper" || die
+}
diff --git a/x11-libs/vte/vte-0.40.2.ebuild b/x11-libs/vte/vte-0.40.2.ebuild
new file mode 100644
index 0000000..518b214
--- /dev/null
+++ b/x11-libs/vte/vte-0.40.2.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+GCONF_DEBUG="no"
+VALA_USE_DEPEND="vapigen"
+
+inherit eutils gnome2 vala
+
+DESCRIPTION="Library providing a virtual terminal emulator widget"
+HOMEPAGE="https://wiki.gnome.org/action/show/Apps/Terminal/VTE"
+
+LICENSE="LGPL-2+"
+SLOT="2.91"
+IUSE="+crypt debug glade +introspection termite-patch vala"
+KEYWORDS="~amd64 ~x86"
+
+PDEPEND=">=x11-libs/gnome-pty-helper-${PV}"
+RDEPEND="
+	>=dev-libs/glib-2.40:2
+	>=x11-libs/gtk+-3.8:3[introspection?]
+	>=x11-libs/pango-1.22.0
+
+	sys-libs/ncurses
+	sys-libs/zlib
+	x11-libs/libX11
+	x11-libs/libXft
+
+	glade? ( >=dev-util/glade-3.9:3.10 )
+	introspection? ( >=dev-libs/gobject-introspection-0.9.0 )
+"
+DEPEND="${RDEPEND}
+	$(vala_depend)
+	>=dev-util/gtk-doc-am-1.13
+	>=dev-util/intltool-0.35
+	sys-devel/gettext
+	virtual/pkgconfig
+
+	crypt?  ( >=net-libs/gnutls-3.2.0 )
+"
+RDEPEND="${RDEPEND}
+	!x11-libs/vte:2.90[glade]
+"
+
+src_prepare() {
+	use termite-patch && epatch "${FILESDIR}"/${PN}-0.32.2-expose_select_text.patch
+
+	vala_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	local myconf=""
+
+	if [[ ${CHOST} == *-interix* ]]; then
+		myconf="${myconf} --disable-Bsymbolic"
+
+		# interix stropts.h is empty...
+		export ac_cv_header_stropts_h=no
+	fi
+
+	# Python bindings are via gobject-introspection
+	# Ex: from gi.repository import Vte
+	# Do not disable gnome-pty-helper, bug #401389
+	gnome2_src_configure \
+		--disable-deprecation \
+		--disable-test-application \
+		--disable-static \
+		$(use_enable debug) \
+		$(use_enable glade glade-catalogue) \
+		$(use_enable crypt gnutls) \
+		$(use_enable introspection) \
+		$(use_enable vala) \
+		${myconf}
+}
+
+src_install() {
+	DOCS="AUTHORS ChangeLog HACKING NEWS README"
+	gnome2_src_install
+	mv "${D}"/etc/profile.d/vte{,-${SLOT}}.sh || die
+}