Add sys-apps/kmod-24

2 files changed, 191 insertions, 0 deletions

diff --git a/sys-apps/kmod/Manifest b/sys-apps/kmod/Manifest
index 8517e051..60da076d 100644
--- a/sys-apps/kmod/Manifest
+++ b/sys-apps/kmod/Manifest
@@ -11,6 +11,7 @@ DIST kmod-20.tar.xz 437880 SHA256 89c1a1a2193c31f9ebe582640bfa2bd401341dc24119f5
 DIST kmod-21.tar.xz 446460 SHA256 160a9448af74cf75b08d089f37a3e8d1fafa75cce92d1cbe869a753b670d95c0 SHA512 93d9c7eda3a04ed94c6531087614d92b5a65a2e642bd3af017a3a8a458a78a5a57acb1707e35bf3a0aa8f22ab0fa99d34cf4e7dd568f202a18eb49fb52bf78c1 WHIRLPOOL 78aa8c086ed8129b3a686f3b7d46e224c09f018fc85cda041bfac253afa8056e3e403eedbedb81be4c2354075040dcb6a526c2295cc3b393a76cb3896491cea3
 DIST kmod-22.tar.xz 449724 SHA256 ba3b1ddea33228b473189fcb05b809024a3b86e9a7cf37d420cae06beb749f82 SHA512 e021bacebb07ba4a178215ca1d1e091195fed1d289a76ec3ddb309182a90b6eab19d98eb1331772bc739f73ed6f540d92213b8088a573df13cd28ebd333a8876 WHIRLPOOL ed5b338698f250a0cb344da0789099a4fcdd098a1d64ed0f912fbb361ee91eaf13ceffec28e95757778a687ed8ed8acce16c0717000c598237e01abda256ca1c
 DIST kmod-23.tar.xz 450376 SHA256 d303d5519faec9d69e1132f6b37db2579db17a7fb5c1517da0115d03ba168155 SHA512 84b18d35117b33c48fd9b732a584a9f94caef553e371bd4e68953540f46fc6c7145c8c7163df898875437ad56e1a47e89be26531314299bce0026c46da9dd3c0 WHIRLPOOL 319fc1c4728e51ef97a4c999ddcf8dc38587028b239a8adf48750335548c3a8e099d3b6a4d1d7a9b3f80ac83609a109d3053dea10ad8b98c2d694494b7f09330
+DIST kmod-24.tar.xz 536864 SHA256 610b8d1df172acc39a4fdf1eaa47a57b04873c82f32152e7a62e29b6ff9cb397 SHA512 58c8da100418b6325de1595bceee4115cbdd7151d03a028c0b1f6d5d3e6611c667e27f3a0245d29781125581849fd1e854fa8d87b63c4b8fa3f196d0a97e1779 WHIRLPOOL f722a515967f8a8cf60e4a053f9227a848230d8b006ca9ba13160b2d5e9f1d4b5abb30f7d4c3c04287da58c7960dd36a5cf7d122036457990b93e0ed42e84195
 EBUILD kmod-15-r1.ebuild 3631 SHA256 3ac06ad8aa645b819700c78075fb50f31edbccb32c2c74f8e0513c3c15c5872c SHA512 34d30771d711b1bb108cf372c97d84c7998630cb339a59484f44f5bf19cdf9d243453a86658bd7ef25279e842317ac780c5a920cf6987f15ff5eaa11d7f1e172 WHIRLPOOL e78c167b3c27dccb45498f5481f3b3126535d5359f63bb3def5e42bfe352cd4f48c83314a3b415800c8dfe78e5a5d55d4551b1debeefa553ecca2ee20ba001ca
 EBUILD kmod-15.ebuild 3608 SHA256 e0d266b7b7c2e87888691801d5145f280a3d63900774432ba09f506eb4c1bf57 SHA512 f961deb2b834222e2352a4f5728aca7eabc0ddadf45802eadc2a16e00c0d0c2152f0c8b5d790356792ea094dfb1602e964b477606ef6ceeebea940db92d6cbbc WHIRLPOOL 4b05c77d5807fa12680ef97c64521e01bbbda06cfd7990b905e5df3724884c31fc213f1688c000d2c9242f6bda067bbf9f24b74acf7a776f0bc87b7bc689cc00
 EBUILD kmod-16.ebuild 3735 SHA256 5325d9ba4144421271f908974a3b50fe74763b1c77a5e6dd4181d0b84592325c SHA512 f1ce4bfddd2ca97d3049909ec27cea3285b911a31aa848bff3af2673ff4bbce2e0f5ba1b039402d1d622e1b1055e5443cad9d2278ffd10dfb852880df6a3eedc WHIRLPOOL 8a506524926f894a7558c49318f252ba39beaa5d6265b006a1c2e37cfaf24ffc2899f4772f4f4aee209c75b64f233905a35e7e1992e7236a0d0f1d40ced97aba
@@ -23,3 +24,4 @@ EBUILD kmod-20.ebuild 4950 SHA256 326c3d5254c7941d583b7b2e999ca5207b86fc1a155822
 EBUILD kmod-21.ebuild 4950 SHA256 5c336a0eb563cf2552c92d701426ec2e6d0151902f57e5da0a5bd760a61500d9 SHA512 6cf7384a1df84b7e07033481a8ed96c2ef48069cbe6aed574ece16906d884869bdd28381469ac3b556feca4483b145637a8834d350f07ea84593d30ea876ace0 WHIRLPOOL f1292aa81ed1d8ef8f3f912080c717a7cdc7782be33bb265f1e344fde57ae074cc94c7cc281b70aa3cf5857eeef2782aa32e26668801d36ba9ace5ee9bc8632e
 EBUILD kmod-22.ebuild 4948 SHA256 aa02421774001e9183cdd1b894a40ee1d39f04b202f477c1b1eedd987b577d48 SHA512 8177bb5a87e9e7ec17a9b7e4f483fd9dba13d7cea1271a44ef4692b652c8cf74bff63e026176b9297efa4c923eaf544e2ff93f6d288ca8894cc9c6ba4268bb82 WHIRLPOOL ac1fb3ae79215663c4aa2cda93d9f967f064a2c37e0de675e11c50a41bc71a53fbaa9b037b87acb4a5677e581ce733f2bd34e3a93650d66d07af9461b534544a
 EBUILD kmod-23.ebuild 4952 SHA256 aa7767c118a222672d1a9e0d3f07bba20fa30bf5fea239e1a55e3eb097d2687b SHA512 39fd6c15464791fa51f8ef003bda1c06886d54f973f5f7f4646fee0554c5775da7b8e68be1d830def7d299b54e9a8f9aed00a044b374e233f73ab1b28dae21b8 WHIRLPOOL a032ee53e6fc0ddb853fe68d0a6a909319e5d08801784d1ffd2a80d169950dea9368b7c52797149db7c771f57399adbf2af2d3fc419e0bcc765802caf604c7d9
+EBUILD kmod-24.ebuild 4913 SHA256 a1a39a977107648e03845af34d6a1b9b637a8cf7cc6bf9a60d26c8facdfefa86 SHA512 1c97638223889cf8a9b177ded5726c8a9a245ba557610bf71361f4168f0dcda5d7ae997aa1a8a77f58c3b6758cf8e39695471fd6fab8b4287c1f2539bbdf27d5 WHIRLPOOL 01b3df12e3e99b4dd5b5dc268f31fd38fefdc6e4b3583753af38e0668e988cb8b0ab8fcb9b0400fc7f2567c30c35ad865f5e0ac80a50cfbefde159c466253bf1
diff --git a/sys-apps/kmod/kmod-24.ebuild b/sys-apps/kmod/kmod-24.ebuild
new file mode 100644
index 00000000..8b936bac
--- /dev/null
+++ b/sys-apps/kmod/kmod-24.ebuild
@@ -0,0 +1,189 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
+
+inherit bash-completion-r1 eutils multilib python-r1
+
+if [[ ${PV} == 9999* ]]; then
+	EGIT_REPO_URI="git://git.kernel.org/pub/scm/utils/kernel/${PN}/${PN}.git"
+	inherit autotools git-2
+else
+	SRC_URI="mirror://kernel/linux/utils/kernel/kmod/${P}.tar.xz"
+	KEYWORDS="~alpha amd64 ~arm ~arm64 hppa ~ia64 ~m68k ~mips ppc ppc64 ~s390 ~sh sparc x86"
+	inherit libtool
+fi
+
+DESCRIPTION="library and tools for managing linux kernel modules"
+HOMEPAGE="https://git.kernel.org/?p=utils/kernel/kmod/kmod.git"
+
+LICENSE="LGPL-2"
+SLOT="0"
+IUSE="debug doc lzma python static-libs +tools zlib"
+
+# Upstream does not support running the test suite with custom configure flags.
+# I was also told that the test suite is intended for kmod developers.
+# So we have to restrict it.
+# See bug #408915.
+RESTRICT="test"
+
+# Block systemd below 217 for -static-nodes-indicate-that-creation-of-static-nodes-.patch
+RDEPEND="!sys-apps/module-init-tools
+	!sys-apps/modutils
+	!<sys-apps/openrc-0.13.8
+	!<sys-apps/systemd-216-r3
+	lzma? ( >=app-arch/xz-utils-5.0.4-r1 )
+	python? ( ${PYTHON_DEPS} )
+	zlib? ( >=sys-libs/zlib-1.2.6 )" #427130
+DEPEND="${RDEPEND}
+	doc? ( dev-util/gtk-doc )
+	lzma? ( virtual/pkgconfig )
+	python? (
+		dev-python/cython[${PYTHON_USEDEP}]
+		virtual/pkgconfig
+		)
+	zlib? ( virtual/pkgconfig )"
+if [[ ${PV} == 9999* ]]; then
+	DEPEND="${DEPEND}
+		dev-libs/libxslt"
+fi
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+DOCS="NEWS README TODO"
+
+src_prepare() {
+	if [ ! -e configure ]; then
+		if use doc; then
+			gtkdocize --copy --docdir libkmod/docs || die
+		else
+			touch libkmod/docs/gtk-doc.make
+		fi
+		eautoreconf
+	else
+		elibtoolize
+	fi
+
+	# Restore possibility of running --enable-static wrt #472608
+	sed -i \
+		-e '/--enable-static is not supported by kmod/s:as_fn_error:echo:' \
+		configure || die
+}
+
+src_configure() {
+	local myeconfargs=(
+		--bindir="${EPREFIX}/bin"
+		--with-rootlibdir="${EPREFIX}/$(get_libdir)"
+		--enable-shared
+		$(use_enable static-libs static)
+		$(use_enable tools)
+		$(use_enable debug)
+		$(use_enable doc gtk-doc)
+		$(use_with lzma xz)
+		$(use_with zlib)
+		--with-bashcompletiondir="$(get_bashcompdir)"
+	)
+
+	local ECONF_SOURCE="${S}"
+
+	kmod_configure() {
+		mkdir -p "${BUILD_DIR}" || die
+		run_in_build_dir econf "${myeconfargs[@]}" "$@"
+	}
+
+	BUILD_DIR="${WORKDIR}/build"
+	kmod_configure --disable-python
+
+	if use python; then
+		python_foreach_impl kmod_configure --enable-python
+	fi
+}
+
+src_compile() {
+	emake -C "${BUILD_DIR}"
+
+	if use python; then
+		local native_builddir=${BUILD_DIR}
+
+		python_compile() {
+			emake -C "${BUILD_DIR}" -f Makefile -f - python \
+				VPATH="${native_builddir}:${S}" \
+				native_builddir="${native_builddir}" \
+				libkmod_python_kmod_{kmod,list,module,_util}_la_LIBADD='$(PYTHON_LIBS) $(native_builddir)/libkmod/libkmod.la' \
+				<<< 'python: $(pkgpyexec_LTLIBRARIES)'
+		}
+
+		python_foreach_impl python_compile
+	fi
+}
+
+src_install() {
+	emake -C "${BUILD_DIR}" DESTDIR="${D}" install
+	einstalldocs
+
+	if use python; then
+		local native_builddir=${BUILD_DIR}
+
+		python_install() {
+			emake -C "${BUILD_DIR}" DESTDIR="${D}" \
+				VPATH="${native_builddir}:${S}" \
+				install-pkgpyexecLTLIBRARIES \
+				install-dist_pkgpyexecPYTHON
+		}
+
+		python_foreach_impl python_install
+	fi
+
+	prune_libtool_files --modules
+
+	if use tools; then
+		local bincmd sbincmd
+		for sbincmd in depmod insmod lsmod modinfo modprobe rmmod; do
+			dosym ../bin/kmod /sbin/${sbincmd}
+		done
+
+		# These are also usable as normal user
+		for bincmd in lsmod modinfo; do
+			dosym kmod /bin/${bincmd}
+		done
+	fi
+
+	cat <<-EOF > "${T}"/usb-load-ehci-first.conf
+	softdep uhci_hcd pre: ehci_hcd
+	softdep ohci_hcd pre: ehci_hcd
+	EOF
+
+	insinto /lib/modprobe.d
+	doins "${T}"/usb-load-ehci-first.conf #260139
+
+	newinitd "${FILESDIR}"/kmod-static-nodes-r1 kmod-static-nodes
+}
+
+pkg_postinst() {
+	if [[ -L ${EROOT%/}/etc/runlevels/boot/static-nodes ]]; then
+		ewarn "Removing old conflicting static-nodes init script from the boot runlevel"
+		rm -f "${EROOT%/}"/etc/runlevels/boot/static-nodes
+	fi
+
+	# Add kmod to the runlevel automatically if this is the first install of this package.
+	if [[ -z ${REPLACING_VERSIONS} ]]; then
+		if [[ ! -d ${EROOT%/}/etc/runlevels/sysinit ]]; then
+			mkdir -p "${EROOT%/}"/etc/runlevels/sysinit
+		fi
+		if [[ -x ${EROOT%/}/etc/init.d/kmod-static-nodes ]]; then
+			ln -s /etc/init.d/kmod-static-nodes "${EROOT%/}"/etc/runlevels/sysinit/kmod-static-nodes
+		fi
+	fi
+
+	if [[ -e ${EROOT%/}/etc/runlevels/sysinit ]]; then
+		if [[ ! -e ${EROOT%/}/etc/runlevels/sysinit/kmod-static-nodes ]]; then
+			ewarn
+			ewarn "You need to add kmod-static-nodes to the sysinit runlevel for"
+			ewarn "kernel modules to have required static nodes!"
+			ewarn "Run this command:"
+			ewarn "\trc-update add kmod-static-nodes sysinit"
+		fi
+	fi
+}